Redbull Ek Alma.

[Takariz]

Serverde Redbull'u 5 Kere kullanma yaptık (o redbull'u 5 kere ek olarak kullanma almak için Jb'den 15 TL gitmesini istiyorum yardımcı olabilecek) ?

[omertas14544]

Jbmenu ve redbull pluginini atınki yardımcı olalım.

[Necati Doğan]

Kod: Tümünü seç

#include <amxmodx>
#include <reapi>
native jb_get_user_packs(id);
native jb_set_user_packs(id, Float:ammount);

#define SERVERISMI "RuthLess Gaming"

new bool:engel[MAX_CLIENTS+1],bool:elbas[MAX_CLIENTS+1],redbullhakki[MAX_CLIENTS+1],redbullhakkicvar,ucret,enfazlahp,kacsaniye,hiz;
public plugin_init() {
	register_plugin("[REAPI] Gelismis Redbull Plugini", "1.1", "Necati_DGN")

	register_clcmd("say /redbull","redbull");
	register_clcmd("say_team /redbull","redbull");
	register_clcmd("radio1", "redbull");
	register_logevent("elbasi", 2, "1=Round_Start");
	register_event("CurWeapon","silahdegis","be");
	RegisterHookChain(RG_CBasePlayer_Killed, "olunce", 1);

	ucret = register_cvar("redbull_fiyat","-1") // Redbull fiyati kac para olsun?
	enfazlahp = register_cvar("redbull_enfazlacan","150") // HP'niz en fazla kaca kadar artsin?
	kacsaniye = register_cvar("redbull_etkisuresi","20.0") // Redbull kac saniye sursun?
	hiz = register_cvar("redbull_hizi","500.0") // Redbull hizi kac olsun?

	redbullhakkicvar = register_cvar("redbull_hakki","5") // Bir roundda kac defa redbull basma hakki olsun? 
							//NOT: 0 yaparsaniz sinirsiz olur. Bence ideali Bir Roundda 3 kere :)
}
public redbull(id) {
	new mahkum,players[MAX_PLAYERS]; get_players(players,mahkum,"acehi","TERRORIST");
	if(engel[id]) client_print_color(id,id,"^1[^3%s^1] ^4Redbull etkisi halen devam ediyor.",SERVERISMI);
	else if(!is_user_alive(id)) client_print_color(id,id,"^1[^3%s^1] ^4Oluyken redbull satin alamazsin.",SERVERISMI);
	else if(mahkum <= 1) client_print_color(id,id,"^1[^3%s^1] ^4Sona bir tane mahkum kalinca redbull satin alamazsiniz.",SERVERISMI);
	else if(redbullhakki[id] >= get_pcvar_num(redbullhakkicvar) && get_pcvar_num(redbullhakkicvar) > 0) {
		if(Float:jb_get_user_packs(id)>=15.00) {
			redbullhakki[id]=0,jb_set_user_packs(id, Float:jb_get_user_packs(id)-15.00);
			client_print_color(id, id, "^1[^3%s^1]^4 Redbull hakkiniz^1 15.00 TL^4 karsiliginda yenilendi.^3 Kalan Hakkiniz :^1 %d",SERVERISMI, get_pcvar_num(redbullhakkicvar)-redbullhakki[id]);
		} else client_print_color(id,id,"^1[^3%s^1] ^4Her roundda ^1%d^4 kere redbull alma hakkiniz var. Tekrar hak alabilmek icin^1 15.00 TL^4 gereklidir.",SERVERISMI,get_pcvar_num(redbullhakkicvar));
	} else if(get_member(id, m_iAccount) < get_pcvar_num(ucret)) {
		client_print_color(id,id,"^1[^3%s^1] ^4Redbull almak icin yeterli paraniz yok. Gereken ^1$%d",SERVERISMI,get_pcvar_num(ucret));
	} else {
		rg_add_account(id, get_member(id, m_iAccount) - get_pcvar_num(ucret), AS_SET);
		engel[id]=true;
		set_task(1.0,"canekleme",id);
		set_task(get_pcvar_float(kacsaniye),"redbullbitir",id);
		set_task(get_pcvar_float(kacsaniye)/2,"redbullbitir3",id);
		set_entvar(id, var_maxspeed, get_pcvar_float(hiz));
		set_entvar(id, var_gravity, 0.5);
		client_print_color(id,id,"^1[^3%s^1] ^4Redbull satin aldiniz. Redbull etkisi ^1%d ^4saniye sonra bitecektir.",SERVERISMI,get_pcvar_num(kacsaniye));
		if(get_pcvar_num(redbullhakkicvar) > 0) {
			redbullhakki[id]++;
			client_print_color(id,id,"^1[^3%s^1] ^4Bu roundda kalan redbull alma hakkiniz : ^1%d",SERVERISMI,get_pcvar_num(redbullhakkicvar)-redbullhakki[id]);
		}
	}
	return PLUGIN_HANDLED;
}
public canekleme(id) {
	if(get_entvar(id, var_health) < get_pcvar_float(enfazlahp) && engel[id]) {
		set_entvar(id, var_health, Float:get_entvar(id, var_health) + 1.0);
		set_task(1.0,"canekleme",id);
	}
}
public redbullbitir(id) {
	engel[id]=false,set_entvar(id, var_maxspeed, 250.0),set_entvar(id, var_gravity, 1.0);
	if(!elbas[id]) client_print_color(id,id,"^1[^3%s^1] ^4Redbull'un etkisi sona erdi.",SERVERISMI);
	else elbas[id]=false;
}
public redbullbitir3(id) client_print_color(id,id,"^1[^3%s^1] ^4Redbull etkisinin bitmesine ^1%d ^4saniye kaldi.",SERVERISMI,get_pcvar_num(kacsaniye)/2);
public olunce(olen, saldiran) {
	new mahkum,players[MAX_PLAYERS]; get_players(players,mahkum,"acehi","TERRORIST");
	if(engel[olen]) redbullbitir(olen),remove_task(olen);
	if(mahkum <= 1) {
		new num,pla[MAX_PLAYERS],ids; get_players(pla,num,"achi");
		for(new i=0; i<num; i++) {
			ids=pla[i];
			if(engel[ids]) redbullbitir(ids),remove_task(ids);
		}
	}
}
public elbasi() {
	new num,pla[MAX_PLAYERS],ids; get_players(pla,num,"chi");
	for(new i=0; i<=num; i++) {
		ids=pla[i];
		redbullhakki[ids]=0;
		if(engel[ids]) elbas[ids]=true,redbullbitir(ids),remove_task(ids);
	}
}
public silahdegis(id) if(engel[id] && is_user_alive(id)) client_cmd(id,"cl_forwardspeed %3.0f;cl_backspeed %3.0f;cl_sidespeed %3.0f",get_pcvar_float(hiz),get_pcvar_float(hiz),get_pcvar_float(hiz)),set_entvar(id, var_maxspeed, get_pcvar_float(hiz));