Redbull mg'ye bağlama

[Takariz]

Redbull verildiğinde mg'den alınsın istiyorum ? ve Redbull En fazla 10 kere kullanılsın mg olsa bile kullanılmasın . Yapabilecek ?

[Necati Doğan]

ucret = register_cvar("redbull_fiyat","10") // Redbull fiyati kac para olsun?

Kod: Tümünü seç

#include <amxmodx>
#include <reapi>
#include <jail>

#define SERVERISMI "CSDuragi"

new engel[33]=0,redbullhakki[33]=0,redbullhakkicvar,ucret,enfazlahp,kacsaniye,mahkum,players[32]
public plugin_init() {
	register_plugin("[REAPI] Gelismis Redbull Plugini", "1.0", "Necati_DGN")

	register_clcmd("say /redbull","redbull")
	register_clcmd("say_team /redbull","redbull")
	register_clcmd("radio1", "redbull")
	register_logevent("elbasi", 2, "1=Round_Start")
	register_event("CurWeapon","silahdegis","be")
	register_event("DeathMsg","olunce","a");

	ucret = register_cvar("redbull_fiyat","10") // Redbull fiyati kac para olsun?
	enfazlahp = register_cvar("redbull_enfazlacan","120") // HP'niz en fazla kaca kadar artsin?
	kacsaniye = register_cvar("redbull_etkisuresi","20") // Redbull kac saniye sursun?

	redbullhakkicvar = register_cvar("redbull_hakki","10") // Bir roundda kac defa redbull basma hakki olsun? 
							//NOT: 0 yaparsaniz sinirsiz olur. Bence ideali Bir Roundda 3 kere :)
}
public redbull(id) {
	get_players(players,mahkum,"ae","TERRORIST")
	if(engel[id]) {
		client_print_color(id,id,"^1[^3%s^1] ^4Redbull etkisi halen devam ediyor.",SERVERISMI)
	} else if(!is_user_alive(id)) {
		client_print_color(id,id,"^1[^3%s^1] ^4Oluyken redbull satin alamazsin.",SERVERISMI)
	} else if(mahkum <= 1) {
		client_print_color(id,id,"^1[^3%s^1] ^4Sona bir tane mahkum kalinca redbull satin alamazsiniz.",SERVERISMI)
	} else if(redbullhakki[id] >= get_pcvar_num(redbullhakkicvar) && get_pcvar_num(redbullhakkicvar) > 0) {
		client_print_color(id,id,"^1[^3%s^1] ^4Her roundda ^1%d^4 kere redbull alma hakkiniz var.",SERVERISMI,get_pcvar_num(redbullhakkicvar))
	} else if(/*get_member(id, m_iAccount)*/jb_get_user_packs(id) < get_pcvar_num(ucret)) {
		client_print_color(id,id,"^1[^3%s^1] ^4Redbull almak icin yeterli paraniz yok. Gereken ^1%d JB",SERVERISMI,get_pcvar_num(ucret))
	} else {
		//rg_add_account(id, get_member(id, m_iAccount) - get_pcvar_num(ucret), AS_SET)
		jb_set_user_packs(id, jb_get_user_packs(id)-get_pcvar_num(ucret))
		engel[id]++
		set_task(1.0,"canekleme",id)
		set_task(get_pcvar_float(kacsaniye),"redbullbitir",id)
		set_task(get_pcvar_float(kacsaniye)/2,"redbullbitir3",id)
		set_entvar(id, var_maxspeed, 400.0)
		set_entvar(id, var_gravity, 0.5)
		client_print_color(id,id,"^1[^3%s^1] ^4Redbull satin aldiniz. Redbull etkisi ^1%d ^4saniye sonra bitecektir.",SERVERISMI,get_pcvar_num(kacsaniye))
		if(get_pcvar_num(redbullhakkicvar) > 0) {
			redbullhakki[id]++
			client_print_color(id,id,"^1[^3%s^1] ^4Bu roundda kalan redbull alma hakkiniz : ^1%d",SERVERISMI,get_pcvar_num(redbullhakkicvar)-redbullhakki[id])
		}
	}
}
public canekleme(id) {
	if(get_entvar(id, var_health) < get_pcvar_float(enfazlahp) && engel[id]) {
		set_entvar(id, var_health, Float:get_entvar(id, var_health) + 1)
		set_task(1.0,"canekleme",id)
	}
}
public redbullbitir(id) {
	engel[id] = 0,set_entvar(id, var_maxspeed, 250.0),set_entvar(id, var_gravity, 1.0);
	client_print_color(id,id,"^1[^3%s^1] ^4Redbull'un etkisi sona erdi.",SERVERISMI)
}
public redbullbitir3(id) client_print_color(id,id,"^1[^3%s^1] ^4Redbull etkisinin bitmesine ^1%d ^4saniye kaldi.",SERVERISMI,get_pcvar_num(kacsaniye)/2);
public olunce() {
	get_players(players,mahkum,"ae","TERRORIST")
	if(mahkum <= 1) {
		for(new ids=1; ids<=get_member_game(m_nMaxPlayers); ids++) {
			if(is_user_alive(ids)) redbullbitir(ids),remove_task(ids);
		}
	}
}
public elbasi() for(new ids=1; ids<=MAX_CLIENTS; ids++) if(is_user_connected(ids)) redbullhakki[ids]=0,engel[ids]=0,remove_task(ids);
public silahdegis(id) if(engel[id] && is_user_alive(id)) client_cmd(id,"cl_forwardspeed 400;cl_backspeed 400;cl_sidespeed 400"),set_entvar(id, var_maxspeed, 400.0);