T ayrı, Ct ayrı

[İmam-POWER]

T de CSGO Default, CT de CSGO default bicak nasıl yaparım?

[ulyoS]

Kod: Tümünü seç

#include < amxmodx >
#include < amxmisc >
#include < cstrike >
#include < hamsandwich >
#include < fakemeta >

#define PLUGIN "Bicaklar"
#define VERSION "1.0"
#define AUTHOR "Anonim"

new g_ctbicak, g_tbicak;

new const CT_BICAK[ ] = "models/bicakc.mdl" ;
new const T_BICAK[ ] = "models/bicakt.mdl";

public plugin_init( ) 
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    RegisterHam( Ham_Item_Deploy, "weapon_knife", "degis", 1 );
    RegisterHam( Ham_Spawn, "player", "dogdu", 1 );
}

public plugin_precache( )
{
    precache_model( CT_BICAK );
    precache_model( T_BICAK );
}

public client_disconnected( id )
{
    g_tbicak &= ~( 1 << ( id & 31 ) );
    g_ctbicak &= ~( 1 << ( id & 31 ) );
}

public dogdu( id )
{
    if( get_user_team( id ) == 1 )
    {
        g_tbicak |= ( 1 << ( id & 31 ) );
    }
    if( get_user_team( id ) == 2 )
    {
        g_ctbicak |= ( 1 << ( id & 31 ) );
    }
}

public degis( f )
{
    new id = get_pdata_cbase( f, 41, 4 )
    
    new weaponID = cs_get_weapon_id( f );
    
    if( !is_user_alive( id ) || !is_user_connected( id ) )
    {
        return HAM_IGNORED;
    }
    
    if( weaponID == CSW_KNIFE )
    {
        if( get_user_team( id ) == 1 && g_tbicak & ( 1 << ( id & 31 ) ) )
        {
            set_pev( id, pev_viewmodel2, T_BICAK )
        }

        if( get_user_team( id ) == 2 && g_ctbicak & ( 1 << ( id & 31 ) ) )
        {
            set_pev( id, pev_viewmodel2, CT_BICAK )
        }
    }
    
    return HAM_IGNORED
}

[ulyoS]

https://gamebanana.com/skins/151080 skinler

[İmam-POWER]

Eywallah kral