Model e komutu ile işlem

[MrFoTo]

O kadar telaşa gerek yoktu ejderyam sen bilirsin ginede teşekkür ederim aklımda güzel bir fikir var hem bu entity olaylarına plugin olarak girmek istiyorum artık çok yardımcı oluyorsun <3

[Fatih ~ EjderYa]

Kod: Tümünü seç

#include <amxmodx>
#include <reapi>
#include <xs>

#define PLUGIN "Eklentı Ismı"
#define VERSION "1.0"
#define AUTHOR "Anonim"

new const BKMODEL[] = "models/player/ng_jb_wachin/ng_jb_wachin.mdl"
new modelindex

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR)
	
	register_clcmd("say /getir","entityGetir")
	
}
public plugin_precache()
{
	
	modelindex = precache_model(BKMODEL)
}
public entityGetir(id){
	
	new ent = rg_create_entity("func_button")
	
	new Float:Konum[3]
	get_entvar(id,var_origin,Konum)
	Konum[2] += 100.0
	set_entvar(ent,var_origin,Konum)
	
	
	set_entvar(ent, var_model, BKMODEL); // Nesneye model ekledim.
	set_entvar(ent, var_modelindex, modelindex); // Nesneye modelindex ekledim.
	
	size_ayarla(ent)
	
	SetUse(ent, "Nesneye_Basildi");
}
public Nesneye_Basildi(ent,id)
{
	client_print(id,print_chat,"islem")
}
size_ayarla(ent)
{

	new Float:size[3],Float:mins[3],Float:maxs[3]
	
	mins[0] = -16.2
	maxs[0] = 16.2
	mins[1] = -16.2
	maxs[1] = 16.2
	mins[2] = -0.0
	maxs[2] = 30.0
	set_entvar(ent, var_mins, mins)
	
	size[0] = (xs_fsign(mins[0]) * mins[0]) + maxs[0]
	size[1] = (xs_fsign(mins[1]) * mins[1]) + maxs[1]
	size[2] = (xs_fsign(mins[2]) * mins[2]) + maxs[2]

	set_entvar(ent, var_maxs, maxs)
	set_entvar(ent, var_size, size)

}

[omertas14544]

Çok iyi bir şekilde canlandı kafamda teşekkürler ama SetUse bu şekilde kullandığım zaman modelin yanına gittiğim zaman e tuşu ile bastığımda herhangi bir sonuç alamıyorum. Birde sen kontrol edermisin.

Kod: Tümünü seç

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <reapi>

#define PLUGIN "Eklentı Ismı"
#define VERSION "1.0"
#define AUTHOR "Anonim"

new BKMODEL[64]
new modelindex
new ent

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR)
	
	register_clcmd("say /getir","entityGetir")
	SetUse(ent, "Nesneye_Basildi");
}
public plugin_precache()
{
	formatex(BKMODEL,charsmax(BKMODEL),"models/player/ng_jb_wachin/ng_jb_wachin.mdl");
	modelindex = precache_model(BKMODEL)
}
public entityGetir(id){
	new classname[32];
	ent = rg_create_entity("info_target") // Ent isminde bir nesne olusturdum.
	set_entvar(ent, var_classname,"anaclass") // Nesneye class atadım.
	set_entvar(ent, var_model, BKMODEL); // Nesneye model ekledim.
	set_entvar(ent, var_modelindex, modelindex); // Nesneye modelindex ekledim.
	set_entvar(ent, var_origin, Float:{213.0, -674.0, 36.0}) // Nesneyi belirledigim koordinatlara isinladim.
	
	get_entvar(ent,var_classname,classname,charsmax(classname));
	client_print(id,print_chat,"%s",classname)
}
public Nesneye_Basildi(ent,id)
{
	client_print(id,print_chat,"islem")
}

SetUse komutunu entityGetir fonksiyonu içerisinde kullanmalısın. Neden der isen, nesnenin kimliğini orada tanımlıyorsun. SetUse fonksiyonunu plugin_init içerisine tanımladığında ent değişkeninde herhangi bir nesne kimliği olmadığı için çalışmayacaktır.

[MrFoTo]

Fatih benim için uğraşıp video çektiğin için çok çok teşekkürler yazışarak'da anlaşabilirdik ama video tabii birazdaha iyi olmuş. Plugini yüklediğim zaman modele e tuşu ile bastığım zaman maalesef bir tepki alamıyorum bir sorun var sanırım.

[Colditz]

Yazdığın eklentiyi buraya atabilir misin?

[MrFoTo]

Fatihin yazdığı eklentiyi deniyorum. Ona bir bak istersen Colditz

[omertas14544]

Kod: Tümünü seç

#include <amxmodx>
#include <reapi>
#include <xs>

#define PLUGIN "Eklentı Ismı"
#define VERSION "1.0"
#define AUTHOR "Anonim"

new const BKMODEL[] = "models/player/ng_jb_wachin/ng_jb_wachin.mdl"
new modelindex

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR)
	
	register_clcmd("say /getir","entityGetir")
	
}
public plugin_precache()
{
	
	modelindex = precache_model(BKMODEL)
}
public entityGetir(id){
	
	new ent = rg_create_entity("func_button")
	
	new Float:Konum[3]
	get_entvar(id,var_origin,Konum)
	Konum[2] += 100.0
	set_entvar(ent,var_origin,Konum)
	set_entvar(ent,var_solid,SOLID_SLIDEBOX)
	
	
	set_entvar(ent, var_model, BKMODEL); // Nesneye model ekledim.
	set_entvar(ent, var_modelindex, modelindex); // Nesneye modelindex ekledim.
	
	size_ayarla(ent)
	
	SetUse(ent, "Nesneye_Basildi");
}
public Nesneye_Basildi(ent,id)
{
	client_print(id,print_chat,"islem")
}
size_ayarla(ent)
{

	new Float:size[3],Float:mins[3],Float:maxs[3]
	
	mins[0] = -16.2
	maxs[0] = 16.2
	mins[1] = -16.2
	maxs[1] = 16.2
	mins[2] = -0.0
	maxs[2] = 30.0
	set_entvar(ent, var_mins, mins)
	
	size[0] = (xs_fsign(mins[0]) * mins[0]) + maxs[0]
	size[1] = (xs_fsign(mins[1]) * mins[1]) + maxs[1]
	size[2] = (xs_fsign(mins[2]) * mins[2]) + maxs[2]

	set_entvar(ent, var_maxs, maxs)
	set_entvar(ent, var_size, size)

}

Bu şekilde test edebilir misin?

[MrFoTo]

Maalesef çalışmadı.

[amad]

Daha önce buna benzer bir eklenti yazdığımda reapi kütüphanesindeki SetUse komutunda bir sıkıntı olduğunu fark etmiştim (belki de ben eksik bir şey yapmış olabilirim ama pek zannetmiyorum). Konudaki ilk yorumumda onun için engine ve hamsandwich kütüphanesiyle yapabileceğini söyledim. Eklenti bu haliyle çalışıyor.

Kod: Tümünü seç

#include <amxmodx>
#include <hamsandwich>
#include <engine>

#define PLUGIN "Eklentı Ismı"
#define VERSION "1.0"
#define AUTHOR "Anonim"

new const BKMODEL[] = "models/player/ng_jb_wachin/ng_jb_wachin.mdl"

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR)
	
	register_clcmd("say /getir","entityGetir")
	RegisterHam(Ham_Use,"func_button","Nesneye_Basildi",1)
}
public plugin_precache()
{
	precache_model(BKMODEL)
}
public entityGetir(id){
	
	new ent = create_entity("func_button")
	entity_set_model(ent, BKMODEL)
	entity_set_size(ent,Float:{-6.0, -10.0, 0.0},Float:{6.0, 10.0, 36.0})
	new Float:f_Origin[3]
	entity_get_vector(id, EV_VEC_origin, f_Origin)    
	f_Origin[0] += 50.0
	entity_set_origin(ent, f_Origin)        
	entity_set_int(ent,EV_INT_solid,SOLID_BBOX)
	drop_to_floor(ent)
}
public Nesneye_Basildi(ent,id)
{
	client_print(id,print_chat,"islem")
}

[MrFoTo]

Evet teşekkürler bu şekilde çalıştı reapi ile ilgili birde fatih bakarsa yada ömer iyi olabilir senin görmediğin ufak bir detayı belki ikisinden biri görebilir teşekkürler amad.