BaseBuilder Sorunsuz Çift Zıplama [ İstek ]

[clawgaming]

Beyler BaseBuildere Göre Uyarlı 2 Kere [ t ] ve [ ct ] de zıplanacak sorunsuz arıyorum bulamadım varmı elinde olan sorunsuz ?? lütfen denenmiş emin olanları atınız teşekkürler.

[TunnS[C]]

Kod: Tümünü seç

#include <amxmodx> 
#include <fakemeta> 
#include <hamsandwich> 

#define ADMIN_MULTIJUMP ADMIN_RESERVATION

#define VERSION "0.0.7" 

#define MAX_PLAYERS 32 

#define m_iTeam 114 
#define m_afButtonPressed 246 
#define m_flFallVelocity 251 

new g_iJumpCount[MAX_PLAYERS+1] 
new g_bMultiJump[MAX_PLAYERS+1 char] 

new g_pCvarMultiJumps, g_pCvarTeamAllowed, g_pCvarOnlyAdmins, g_pCvarMaxFallVelocity, g_pCvarJumpVelocity

public plugin_init() 
{ 
    register_plugin("Multi Jumps", VERSION, "ConnorMcLeod")

    g_pCvarMultiJumps = register_cvar("mp_multijumps", "2")
    g_pCvarTeamAllowed = register_cvar("mp_multijumps_team", "3") //0:nobody, 1:terrorists, 2:cts, 3:all
    g_pCvarOnlyAdmins = register_cvar("mp_multijumps_adminonly", "1")
    g_pCvarMaxFallVelocity = register_cvar("mp_multijump_maxfallvelocity", "99999999999")
    g_pCvarJumpVelocity = register_cvar("mp_multijumps_jumpvelocity", "333")

    register_clcmd("say /mj", "ClCmd_Say_MultiJump")
    register_clcmd("say /multijump", "ClCmd_Say_MultiJump")

    RegisterHam(Ham_Player_Jump, "player", "OnCBasePlayer_Jump", false)
} 

public client_putinserver( id ) 
{ 
    g_bMultiJump{ id } = true 
} 

public ClCmd_Say_MultiJump( id ) 
{ 
    client_print(id, print_chat, " * MultiJumps : %sable", ( g_bMultiJump{ id } = !g_bMultiJump{ id } ) ? "en" : "dis")
} 

public OnCBasePlayer_Jump(id) 
{ 
    if( !g_bMultiJump{ id } || !is_user_alive(id) )
    { 
        return HAM_IGNORED 
    } 

    new fFlags = pev(id, pev_flags) 
    if(    fFlags & FL_WATERJUMP 
    ||    pev(id, pev_waterlevel) >= 2 
    ||    !(get_pdata_int(id, m_afButtonPressed) & IN_JUMP)    )
    { 
        return HAM_IGNORED 
    } 

    if(    fFlags & FL_ONGROUND    ) 
    { 
        g_iJumpCount[id] = 0 
        return HAM_IGNORED 
    } 

    new iMulti = get_pcvar_num(g_pCvarMultiJumps)

    if( iMulti ) 
    { 
        if(    get_pcvar_num(g_pCvarTeamAllowed) & get_pdata_int(id, m_iTeam)
        ||    ( get_pcvar_num(g_pCvarOnlyAdmins) && get_user_flags(id) & ADMIN_MULTIJUMP )    )
        { 
            if(    get_pdata_float(id, m_flFallVelocity) < get_pcvar_float(g_pCvarMaxFallVelocity)
            &&    ++g_iJumpCount[id] <= iMulti    )
            { 
                new Float:fVelocity[3] 
                pev(id, pev_velocity, fVelocity)
                fVelocity[2] = get_pcvar_float(g_pCvarJumpVelocity)
                set_pev(id, pev_velocity, fVelocity)
                return HAM_HANDLED 
            } 
        } 
    } 

    return HAM_IGNORED 
}  

[clawgaming]

213.238.173.58 gelirsen buyur 3 kere zıplıyorlar

[emirakpinar]

Cvar ayarlarından mp_multijumps "1" yapıp dener misin?

[TunnS[C]]

Sorunlu çift zıplama yoktur sorunlu kullanıcı vardır insan cvar kodlarına biraz bakar

[emirakpinar]

[clawgaming]

kardeş ben orda ne yazdığımı belirtmişim sma yok elimde yapıyorsan tam atı ver eyvallah iyi forumlar.