Discord sunucumuz açılmıştır, hepinizi bekleriz

https://discord.gg/43gGDQe6tS

Amx Bank

Eklenti sorunlarınız ve özel eklenti istekleriniz

Moderatör: Moderatörler

Cevapla

Konu Sahibi
godlike
Mesajlar: 35
Kayıt: Çrş Şub 01, 2017 8:39 pm

Amx Bank

Mesaj gönderen godlike »

Merhaba,

Amx bank pluginin kurdum. Fakat plugin komutları sadece konsoldan çalışıyor. Chatten yazdığımdan Unknown command: amx_bank_menu hatasını alıyorum. Bu sorunu yaşayan oldumu hiç?
Link:
Linklerini gizle
Linki Kopyala
Başa dön
Kullanıcı avatarı

Mustafa Kemal1
Mesajlar: 2058
Kayıt: Sal Oca 10, 2017 4:03 pm
Server Ip/DNS: csxx. Csduragi.com
Clan İsmi: kaoS GamınG
İletişim:
İletişim Mustafa Kemal1

Amx Bank

Mesaj gönderen Mustafa Kemal1 »

Yüklerken cıkan warnıngler yuzunden olmus olabilr sma atarsan yardım edebiliriz
Link:
Linklerini gizle
Linki Kopyala
Başa dön

Konu Sahibi
godlike
Mesajlar: 35
Kayıt: Çrş Şub 01, 2017 8:39 pm

Amx Bank

Mesaj gönderen godlike »

Ekledim.Ayrıca Türkçeye çevirmiştim.
Bu mesaja eklenen dosyaları görüntülemek için gerekli izinlere sahip değilsiniz.
Link:
Linklerini gizle
Linki Kopyala
Başa dön

PaZee
Mesajlar: 1761
Kayıt: Çrş Şub 22, 2017 11:28 pm
Konum: Istanbul
Server Ip/DNS: Cs.teknoklan.com
Clan İsmi: TeknoKlan
İletişim:
İletişim PaZee

Amx Bank

Mesaj gönderen PaZee »

buyrun ;

Kod: Tümünü seç

#define SQLON 0 // 1 = Use SQL | 0 = Use file

#include <amxmodx>
#include <amxmisc>
#include <cstrike>

new HELPPAGE[] = "http://home.netcom.com/~everco_ice/bankhelp17.html"

new bool:canuse[33] = false
new interest[33] = 0
new bankfees = 0
new rounds = 0
new sayspecial[33] = 0

#if SQLON
	#include <dbi>
#else
	#include <vault>
#endif

#if SQLON
	new Sql:dbc
	new Result:result
#else
	new allowfilepath[251]
#endif

public plugin_init()
{
	register_plugin("Banka","1.7","twistedeuphoria")
	register_clcmd("say /banka","bank_menu")
	register_clcmd("say_team /banka","bank_menu"
	register_concmd("bank_create","bank_create",ADMIN_USER,"Yeni Banka Hesabi Olustur")
	register_concmd("bank_close","bank_close",ADMIN_CVAR,"Kapat")
	register_concmd("bank_open","bank_open",ADMIN_CVAR,"Bankaya gir")
	register_concmd("bank_amount","bank_amount",ADMIN_USER,"Bankadaki Para Miktarini Goster")
	register_concmd("bank_deposit","bank_deposit",ADMIN_USER,"<amount> :Bankaya Para Yatir")
	register_concmd("bank_withdraw","bank_withdrawl",ADMIN_USER,"<amount> :Bankadan Para Cek")
	register_concmd("bank_help","bank_help",ADMIN_USER,"Yardim")
	register_concmd("bank_transfer","bank_transfer",ADMIN_USER,"<user> <amount> : Baska Hesaba Para Gonder")
	register_concmd("bank_givemoney","bank_givemoney",ADMIN_CVAR,"<user> <amount> : Baskasina Para Ver")
	register_concmd("bank_menu","bank_menu",ADMIN_USER,"Banka Menusunu Ac")
	register_concmd("maxdep","deposit_maximum",ADMIN_USER,"Butun Parayi Bankaya Yatir")
	register_concmd("maxwit","withdrawl_maximum",ADMIN_USER,"En Fazla 16000$ Cekebilirsiniz")
	register_clcmd("say","say_cheese")
	register_clcmd("say_team","say_cheese")
	register_cvar("bank_default_opening","1000")
	register_cvar("bank_state","1")
	register_cvar("bank_min_players","1")
	register_cvar("bank_restrict","0") // 0 = All user can use the bank 1 = Only users defined in file or SQL
	register_cvar("bank_interest_rounds","15")
	register_cvar("bank_interest_rate","0.01")
	register_cvar("bank_fees_base","0")  //Base bank fee in $
	register_cvar("bank_fees_increase","0") //Added to the base fee for each transaction in a round
	register_cvar("bank_offrounds","1") //How many rounds from the start of the map will bank be off for
	register_cvar("bank_msg_interval","60")
	register_cvar("bank_msg","")
	register_cvar("bank_use_ip","0")
	register_menucmd(register_menuid("Banka Menu:"),1023,"bank_menu_cmd")
	register_logevent("giveinterest",2,"0=World triggered","1=Round_Start")
	register_event("Money", "hookmoney", "b") 
	#if SQLON
		set_task(5.0,"sqlinit")
	#else
		new directory[201]
		get_configsdir(directory,200)
		if(get_cvar_num("bank_restrict") == 2)
		{
			formatex(allowfilepath,250,"%s/bankusers.ini",directory)
			if(!file_exists(allowfilepath))
			{
				new writestr[101]
				formatex(writestr,100,";Put all users who can use the bank in here.")
				write_file(allowfilepath,writestr)
			}			
		}
	#endif
	set_task(float(get_cvar_num("bank_msg_interval")),"bank_spam")
}

public check_use(id,pos)
{
	if(id)
	{
		if(canuse[id] == false)
		{
			if(pos)
				client_print(id,print_chat,"Bankayi Kullanamazsiniz")
			else
				console_print(id,"Bankayi Kullanamazsiniz")
			return 0
		}
	}
	new cvarrounds = get_cvar_num("bank_offrounds")
	if(rounds <= cvarrounds)
	{
		if(pos)
			client_print(id,print_chat,"Sorry, the bank is disabled for the first %d rounds of the map.",cvarrounds)
		else
			console_print(id,"Sorry, the bank is disabled for the first %d rounds of the map.",cvarrounds)
		return 0
	}
	if(!get_cvar_num("bank_state"))
	{
		if(pos)
			client_print(id,print_chat,"Sorry, the bank is closed and no transactions are being processed.")
		else
			console_print(id,"Sorry, the bank is closed and no transactions are being processed.")
		return 0
	}
	new players = get_playersnum()
	new minplayers = get_cvar_num("bank_min_players")
	if(players < minplayers)
	{
		if(pos)
			client_print(id,print_chat,"There must be at least %d players connected to use the bank.",minplayers)
		else
			console_print(id,"There must be at least %d players connected to use the bank.",minplayers)
		return 0
	}
	return 1
}

public get_balance(id)
{
	new sid[35]
	new balance = -1
	if(get_cvar_num("bank_use_ip"))
		get_user_ip(id,sid,34)
	else
		get_user_authid(id,sid,34)
	#if SQLON
		result = dbi_query(dbc,"SELECT * FROM bank WHERE sid = '%s'",sid)
		if(result == RESULT_NONE)
			dbi_free_result(result)
		else
		{
			dbi_nextrow(result)
			balance = dbi_result(result,"amount")
			dbi_free_result(result)
		}
	#else
		new key[51]
		formatex(key,50,"%s_account",sid)
		if(vaultdata_exists(key))
		{
			new balancestr[21]
			get_vaultdata(key,balancestr,20)
			balance = str_to_num(balancestr)
		}
	#endif
	return balance
}

public set_balance(id,balance)
{
	new sid[35]
	if(get_cvar_num("bank_use_ip"))
		get_user_ip(id,sid,34)
	else
		get_user_authid(id,sid,34)
	#if SQLON
		result = dbi_query(dbc,"UPDATE bank SET amount = '%d' WHERE sid = '%s'",balance,sid)
		if(result == RESULT_NONE)
		{
			dbi_free_result(result)
			return -1
		}
		else
			return 1
	#else
		new key[51]
		formatex(key,50,"%s_account",sid)
		if(vaultdata_exists(key))
		{
			new balancestr[21]
			num_to_str(balance,balancestr,20)
			set_vaultdata(key,balancestr)
			return 1
		}
		else
			return -1
	#endif
	return -1	
}

public bank_menu(id)
{
	new client = 0
	if(read_argc() > 1)
		client = 1
	if(!check_use(id,client)) return PLUGIN_HANDLED
	new menubody[276], keys = 0,len
	new bool:hasacc = true
	len = format(menubody,275,"\yBanka Menu:\w^n")
	if(get_balance(id) == -1)
	{
		hasacc = false
		len += format(menubody[len],275-len,"1. Banka Hesabi Ac^n\d")
		keys |= (1<<0|1<<9)		
	}
	else
		len += format(menubody[len],275-len,"\d1. Banka Hesabi Ac^n\w")
	len += format(menubody[len],275-len,"2. Hesabi Kontrol Et^n3. Para Yatir^n4. Hepsini Yatir^n5. Para Cek^n6. Butun Parayi Cek^n7. Banka Yardim^n8. Para Gonder^n^n")
	if(hasacc)
	{
		len += format(menubody[len],275-len,"0. Cikis")
		keys |= (1<<1|1<<2|1<<3|1<<4|1<<5|1<<6|1<<7|1<<9)
	}
	else
		len += format(menubody[len],275-len,"\w0. Cikis")
	show_menu(id,keys,menubody,-1,"Banka Menu:")
	return PLUGIN_CONTINUE
}

public bank_menu_cmd(id,key)
{
	switch(key)
	{
		case 0: client_cmd(id,"bank_create 1")
		case 1: client_cmd(id,"bank_amount 1")
		case 2:
		{
			sayspecial[id] = 1
			client_print(id,print_chat,"Lutfen Yatirmak Istediginiz Mikatri Yaziniz:")
		}			
		case 3: client_cmd(id,"maxdep")
		case 4:
		{	
			sayspecial[id] = 2
			client_print(id,print_chat,"Lutfen Cekmek Istediginiz Miktari Yaziniz:")
		}
		case 5: client_cmd(id,"maxwit")
		case 6:	client_cmd(id,"bank_help")
		case 7:
		{
			sayspecial[id] = 3
			client_print(id,print_chat,"Lutfen Baskasina Gondermek Istediginiz Miktari Yaziniz:")
		}
	}
	return PLUGIN_HANDLED
}

public bank_givemoney(id,level,cid)
{
	if(!cmd_access(id,level,cid,3))
		return PLUGIN_HANDLED
	new target[32], tid
	read_argv(1,target,31)
	tid = cmd_target(id,target,2)
	if(!tid)
		return PLUGIN_HANDLED
	new amountstr[10], amount
	read_argv(2,amountstr,9)
	amount = str_to_num(amountstr)
	new totam = amount
	new curmoney = cs_get_user_money(tid)
	new newtotal = curmoney + amount
	if(newtotal > 16000)
	{		
		cs_set_user_money(tid,16000)
		amount = newtotal - 16000
	}
	else
	{
		cs_set_user_money(tid,newtotal)
		amount = 0
	}
	if(amount > 0)
	{	
		new balance = get_balance(tid)
		if(balance != -1)
			set_balance(id,balance + amount)
	}
	new name[32], tname[32]
	get_user_name(id,name,31)
	get_user_name(tid,tname,31)
	if(read_argc() == 4)
		client_print(id,print_chat,"You gave %s $%d.",tname,totam)
	else
		console_print(id,"You gave %s $%d.",tname,totam)
	client_print(tid,print_chat,"%s gave you $%d, $%d of which went into your bank account.",name,totam,amount)
	return PLUGIN_HANDLED
}	

public bank_transfer(id)
{
	new client = 0
	if(read_argc() > 3)
		client = 1
	if(!check_use(id,client)) return PLUGIN_HANDLED
	new target[32]
	read_argv(1,target,31)
	new tgt = cmd_target(id,target,8)
	if(!tgt)
		return PLUGIN_HANDLED
	if(id == tgt)
	{
		if(client)
			client_print(id,print_chat,"Kendinize Para Gonderemezsinz")
		else
			console_print(id,"Kendinize Para Gonderemezsinz")
		return PLUGIN_HANDLED
	}		
	new tamounts[9],tamount
	read_argv(2,tamounts,8)
	tamount = str_to_num(tamounts)
	if(tamount <= 0) return PLUGIN_HANDLED
	new balance = get_balance(id)
	if(balance == -1)
	{
		if(client)
			client_print(id,print_chat,"Para Gondermek Icin Banka Hesabiniz Yoktur")
		else
			console_print(id,"Para Gondermek Icin Banka Hesabiniz Yoktur")
		return PLUGIN_HANDLED
	}
	new tbalance = get_balance(tgt)
	new name[32], tname[32]
	get_user_name(tgt,tname,31)
	get_user_name(id,name,31)	
	if(tbalance == -1)
	{
		if(client)
			client_print(id,print_chat,"%s para transferi icin banka hesabi yoktur.",tname)
		else
			console_print(id,"%s does not have a bank account to transfer money to.",tname)
		client_print(tgt,print_chat,"%s size para gondermeyi denedi.Fakat sizin banka hesabiniz yok!",name)
		return PLUGIN_HANDLED
	}	
	balance -= tamount
	balance -= bankfees
	if(balance < 0)
	{
		if(client)
			client_print(id,print_chat,"Banka Hesabinizda Yeterli Para Yoktur")
		else
			console_print(id,"Banka Hesabinizda Yeterli Para Yoktur")
		return PLUGIN_HANDLED
	}
	tbalance += tamount
	if(bankfees > 0)
	{
		if(client)
			client_print(id,print_chat,"Bankanizdan $%d Odeme Yaptiniz.",bankfees)
		else
			console_print(id,"Bankanizdan $%d Odeme Yaptiniz.",bankfees)
	}		
	set_balance(id,balance)
	set_balance(tgt,tbalance)
	if(client)
		client_print(id,print_chat,"$%d to %s's Hesabinizdan Para Gonderdiniz. Suanda Bankanizda $%d Bulunmaktadir.",tamount,tname,balance)
	else
		console_print(id,"$%d to %s's Hesabinizdan Para Gonderdiniz. Suanda Bankanizda $%d Bulunmaktadir.",tamount,tname,balance)
	client_print(tgt,print_chat,"%s size $%d para gonderdi. Suanda hesabinizda $%d bulunmaktadir.",name,tamount,tbalance)
	return PLUGIN_HANDLED
}


public hookmoney()
{
	if(!get_cvar_num("bank_state"))
		return PLUGIN_CONTINUE
	new curmoney = read_data(1)
	if(curmoney < 16000)
		return PLUGIN_CONTINUE
	new id
	for(new inum=0;inum<=32;inum++)
	{
		if(!is_user_connected(inum)) continue
		new rmoney = cs_get_user_money(inum)
		if(rmoney == curmoney)
		{
			id = inum
			break;
		}
	}
	if(canuse[id] == false)
		return PLUGIN_CONTINUE
	new cvarrounds = get_cvar_num("bank_offrounds")
	if(rounds <= cvarrounds)
		return PLUGIN_CONTINUE
	if(get_playersnum() >= get_cvar_num("bank_min_players"))
	{
		new balance = get_balance(id)
		if(balance == -1)
			return PLUGIN_CONTINUE
		balance += 10000
		set_balance(id,balance)
		cs_set_user_money(id,curmoney-10000)
		client_print(id,print_chat,"$10000 otomatik olarak banka hesabiniza yatirildi. Toplam Bankadaki Paraniz $%d",balance)
	}
	return PLUGIN_CONTINUE
}

public bank_spam()
{
	new cvarval = get_cvar_num("bank_state")
	if(cvarval)
	{
		new message[256]
		get_cvar_string("bank_msg",message,255)
		client_print(0,print_chat,message)
	}
	set_task(float(get_cvar_num("bank_msg_interval")),"bank_spam")
}

public bank_help(id)
{
	show_motd(id,HELPPAGE,"AMX Bank Help")
}

public say_cheese(id)
{
	new said[191]
	read_args(said,190)
	remove_quotes(said)
	if(sayspecial[id])
	{
		switch(sayspecial[id])
		{
			case 1: client_cmd(id,"bank_deposit %s 1",said)
			case 2: client_cmd(id,"bank_withdraw %s 1",said)
			case 3: client_cmd(id,"bank_transfer %s 1",said)
		}
		sayspecial[id] = 0
		return PLUGIN_HANDLED
	}				
	if(said[0] == 'm')
	{
		if(equali(said,"maxwit"))
		{
			withdrawl_maximum(id)
			return PLUGIN_HANDLED
		}
		if(equali(said,"maxdep"))
		{
			deposit_maximum(id)
			return PLUGIN_HANDLED
		}
	}
	else if(said[0] == 'b')
	{
		if(containi(said,"bank_") != -1)
		{
			if(equali(said,"bank_amount"))
			{
				client_cmd(id,"bank_amount 1")
				return PLUGIN_HANDLED
			}
			if(containi(said,"bank_withdraw") != -1)
			{
				replace(said,190,"bank_withdraw","")
				client_cmd(id,"bank_withdraw %s 1",said)
				return PLUGIN_HANDLED
			}
			if(containi(said,"bank_deposit") != -1)
			{
				replace(said,190,"bank_deposit","")
				client_cmd(id,"bank_deposit %s 1",said)
				return PLUGIN_HANDLED
			}
			if(containi(said,"bank_transfer") != -1)
			{
				replace(said,190,"bank_transfer","")
				new target[51],amountstr[51]
				parse(said,target,50,amountstr,50)
				client_cmd(id,"bank_transfer %s %s 1",target,amountstr)
				return PLUGIN_HANDLED
			}
			if(containi(said,"bank_givemoney") != -1)
			{
				replace(said,190,"bank_givemoney","")
				new target[51],amountstr[51]
				parse(said,target,50,amountstr,50)
				client_cmd(id,"bank_givemoney %s %s 1",target,amountstr)
				return PLUGIN_HANDLED
			}
			if(equali(said,"bank_create"))
			{
				client_cmd(id,"bank_create 1")
				return PLUGIN_HANDLED
			}			
			if(equali(said,"bank_help"))
			{
				bank_help(id)
				return PLUGIN_HANDLED
			}
			if(equali(said,"bank_open"))
			{
				client_cmd(id,"bank_open 1")
				return PLUGIN_HANDLED
			}
			if(equali(said,"bank_close"))
			{
				client_cmd(id,"bank_close 1")
				return PLUGIN_HANDLED
			}					
			if(equali(said,"bank_menu"))
			{
				client_cmd(id,"bank_menu")
				return PLUGIN_HANDLED
			}
		}
	}
	return PLUGIN_CONTINUE
}

public giveinterest()
{
	rounds++
	if(!check_use(0,1)) return PLUGIN_CONTINUE
	bankfees = get_cvar_num("bank_fees_base")
	new Float:rate = get_cvar_float("bank_interest_rate")
	new irounds = get_cvar_num("bank_interest_rounds")
	if(!get_cvar_num("bank_state"))
		return PLUGIN_CONTINUE
	for(new i = 1;i<=32;i++)
	{
		if(is_user_connected(i))
		{
			if(canuse[i])
			{
				interest[i]++
				if(interest[i] >= irounds)
				{
					interest[i] = 0
					new balance = get_balance(i)
					if(balance != -1)
					{
						new Float:give = floatmul(rate,float(balance))
						new givint = floatround(give)
						if(givint > 0)
						{
							new allowed = 16000 - cs_get_user_money(i)
							if(givint <= allowed)
							{
								cs_set_user_money(i,cs_get_user_money(i)+givint)
								client_print(i,print_chat,"You were given $%d in interest.",givint)
							}
							else
							{
								new dep = givint - allowed
								client_print(i,print_chat,"You were given $%d in interest $%d of which went into your account.",givint,dep)
								cs_set_user_money(i,16000)
								balance += dep
								set_balance(i,balance)
							}
						}
					}
				}
			}
		}
	}
	return PLUGIN_CONTINUE
}

public client_putinserver(id)
{
	interest[id] = 0
	canuse[id] = false
	switch(get_cvar_num("bank_restrict"))
	{
		case 0:
		{
			canuse[id] = true
		}
		case 1:
		{
			if(access(id,ADMIN_CHAT))
				canuse[id] = true
			else
				canuse[id] = false
		}
		case 2:
		{
			canuse[id] = false
			new sid[35]
			if(get_cvar_num("bank_use_ip"))
				get_user_ip(id,sid,34,1)
			else
				get_user_authid(id,sid,34)
			#if SQLON	
				result = dbi_query(dbc,"SELECT * FROM bankusers WHERE sid = '%s'",sid)
				if(result == RESULT_NONE)
					canuse[id] = false
				else
					canuse[id] = true
				dbi_free_result(result)
			#else
				new retstr[35],a,i
				while(read_file(allowfilepath,i,retstr,34,a))
				{
					if(equali(sid,retstr))
						canuse[id] = true
					i++
				}
			#endif
		}
	}
}	

public client_disconnect(id)
{
	canuse[id] = false
	interest[id] = 0
}

public deposit_maximum(id)	
{
	if(!check_use(id,1)) return PLUGIN_HANDLED	
	new curmoney = cs_get_user_money(id)
	new balance = get_balance(id)
	if(balance == -1)
	{
		client_print(id,print_chat,"Bir Banka Hesabiniz Yok.")
		return PLUGIN_HANDLED	
	}
	balance += curmoney
	set_balance(id,balance)
	cs_set_user_money(id,0)
	client_print(id,print_chat,"Banka hesabiniza $%d Yatirdiniz. Simdi $%d Paraniz Var.",curmoney,balance)
	return PLUGIN_HANDLED
}

public withdrawl_maximum(id)
{
	if(!check_use(id,1)) return PLUGIN_HANDLED
	new balance = get_balance(id)
	if(balance == -1)
	{
		client_print(id,print_chat,"Bir Banka Hesabiniz Yok.")
		return PLUGIN_HANDLED
	}
	new curmoney = cs_get_user_money(id)
	new maxmoney = 16000 - cs_get_user_money(id)
	if(maxmoney > balance)
		maxmoney = balance
	balance -= maxmoney
	cs_set_user_money(id,curmoney + maxmoney,1)
	if((balance - bankfees) > 0)
		balance -= bankfees
	else
		cs_set_user_money(id,cs_get_user_money(id) - bankfees)
	if(bankfees > 0)
		client_print(id,print_chat,"You paid $%d in bank fees.",bankfees)
	bankfees += get_cvar_num("bank_fees_increase")		
	set_balance(id,balance)
	client_print(id,print_chat,"Banka Hesabinizdan $%d Para Cektiniz. Simdi $%d Paraniz Var.",maxmoney,balance)
	return PLUGIN_HANDLED
}
	
public bank_amount(id)
{
	new client = 0
	if(read_argc() > 1)
		client = 1
	if(!check_use(id,client)) return PLUGIN_HANDLED
	new balance = get_balance(id)
	if(balance == -1)
	{
		if(client)
			client_print(id,print_chat,"Bir Banka Hesabiniz Yok.")
		else
			console_print(id,"Bir Banka Hesabiniz Yok.")
		return PLUGIN_HANDLED		
	}
	else
	{
		if(client)
			client_print(id,print_chat,"Bankaniza $%d Paraniz Bulunmaktadir.",balance)
		else
			console_print(id,"Bankaniza $%d Paraniz Bulunmaktadir.",balance)
	}
	return PLUGIN_HANDLED
}

public bank_open(id,level,cid)
{
	if(!cmd_access(id,level,cid,1))
		return PLUGIN_HANDLED
	new client = 0
	if(read_argc() > 1)
		client = 1
	if(get_cvar_num("bank_state"))
	{
		if(client)
			client_print(id,print_chat,"The AMX bank is already open.")
		else
			console_print(id,"The AMX bank is already open.")
	}
	else
	{
		console_cmd(id,"amx_cvar bank_state 1")
		if(get_cvar_num("bank_state"))
		{
			if(client)
				client_print(id,print_chat,"The bank is now open.")
			else
				console_print(id,"The bank is now open.")
			client_print(0,print_chat,"The bank is now open for business.")
		}		
		else
		{
			if(client)
				client_print(id,print_chat,"You may not open the bank.")
			else
				console_print(id,"You may not open the bank.")
		}	
	}
	return PLUGIN_HANDLED
}

public bank_close(id,level,cid)
{	
	if(!cmd_access(id,level,cid,1))
		return PLUGIN_HANDLED
	new client = 0 
	if(read_argc() > 1)
		client = 1
	if(!get_cvar_num("bank_state"))
	{
		if(client)
			client_print(id,print_chat,"Banka Zaten Kapali.")
		else
			console_print(id,"Banka Zaten Kapali.")
	}
	else
	{
		console_cmd(id,"amx_cvar bank_state 0")
		if(!get_cvar_num("bank_state"))
		{
			if(client)
				client_print(id,print_chat,"Banka Kapatildi.")
			else
				console_print(id,"Banka Kapatildi.")
			client_print(0,print_chat,"Banka Kapatildi.")
		}		
		else
		{
			if(client)
				client_print(id,print_chat,"Bankayi Kapatamazsiniz.")
			else
				console_print(id,"Bankayi Kapatamazsiniz.")
		}	
	}
	return PLUGIN_HANDLED
}

public sqlinit()
{
	#if SQLON
		new error[32],sqlhostname[35],sqluser[35],sqlpass[35],sqldbname[35]
		get_cvar_string("amx_sql_host",sqlhostname,34)
		get_cvar_string("amx_sql_user",sqluser,34)
		get_cvar_string("amx_sql_pass",sqlpass,34)
		get_cvar_string("amx_sql_db",sqldbname,34)
		dbc = dbi_connect(sqlhostname,sqluser,sqlpass,sqldbname,error,31)
		if(dbc == SQL_FAILED)
		{
			server_print("Could not connect.")
			return PLUGIN_HANDLED
		}
		result = dbi_query(dbc,"CREATE TABLE IF NOT EXISTS `bank` (`sid` VARCHAR(35), `amount` BIGINT(20))")
		dbi_free_result(result)
		result = dbi_query(dbc,"CREATE TABLE IF NOT EXISTS `bankusers` (`sid` VARCHAR(35), `comments` VARCHAR(100))")
		dbi_free_result(result)
	#endif
	return 1
}

public bank_create(id)
{
	new client = 0
	if(read_argc() > 1)
		client = 1
	if(!check_use(id,client)) return PLUGIN_HANDLED
	new curmoney,neededmoney, amount
	neededmoney = get_cvar_num("bank_default_opening")
	curmoney = cs_get_user_money(id)
	if(curmoney >= neededmoney)
	{
		amount = neededmoney
		curmoney -= neededmoney
	}
	else
	{
		amount = curmoney
		curmoney = 0
	}
	#if SQLON
		new sid[35]
		if(get_cvar_num("bank_use_ip"))
			get_user_ip(id,sid,34,1)
		else
			get_user_authid(id,sid,34)
		result = dbi_query(dbc,"SELECT * FROM bank WHERE sid = '%s'",sid)
		if(result != RESULT_NONE)
		{
			if(client)
				client_print(id,print_chat,"Zaten Bir Hesabiniz Var!")
			else
				console_print(id,"Zaten Bir Hesabiniz Var!")
			return PLUGIN_HANDLED
		}
		dbi_free_result(result)
		result = dbi_query(dbc,"INSERT INTO bank VALUES ( '%s' , '%d')",sid,amount)
		dbi_free_result(result)
	#else
		new sid[35],key[51]
		if(get_cvar_num("bank_use_ip"))
			get_user_ip(id,sid,34,1)
		else
			get_user_authid(id,sid,34)
		format(key,50,"%s_account",sid)
		if(vaultdata_exists(key))
		{
			if(client)
				client_print(id,print_chat,"Zaten Bir Banka Hesabiniz Var!")
			else
				console_print(id,"Zaten Bir Banka Hesabiniz Var!")
			return PLUGIN_HANDLED
		}
		new saveamstr[21]
		num_to_str(amount,saveamstr,20)
		set_vaultdata(key,saveamstr)
	#endif			
	cs_set_user_money(id,curmoney)
	if(client)
		client_print(id,print_chat,"Banka Hesabi Yaratildi. Hesabiniza $%d Yatiridi.",amount)
	else
		console_print(id,"Banka Hesabi Yaratildi. Hesabiniza $%d Yatiridi.",amount)
	return PLUGIN_HANDLED
}

public bank_withdrawl(id)
{
	new client = 0
	if(read_argc() > 2)
		client = 1
	if(!check_use(id,client)) return PLUGIN_HANDLED
	new balance = get_balance(id)
	if(balance == -1)
	{
		if(client)
			client_print(id,print_chat,"Banka Hesabiniz Yok.Lutfen Banka Hesabi Aciniz.")
		else
			console_print(id,"Banka Hesabiniz Yok. Lutfen Banka Hesabi Aciniz.")
		return PLUGIN_HANDLED		
	}
	new ams[9],amn,maxam	
	read_args(ams,8)
	amn = str_to_num(ams)
	if(amn <= 0) return PLUGIN_HANDLED	
	maxam = 16000 - cs_get_user_money(id)
	if(amn > maxam)
		amn = maxam
	if(amn > balance)
	{
		if(client)
			client_print(id,print_chat,"Banka Hesabinizda Yeteri Kadar Para Yok.")
		else
			console_print(id,"Banka Hesabinizda Yeteri Kadar Para Yok.")
		return PLUGIN_HANDLED
	}
	balance -= amn
	cs_set_user_money(id,cs_get_user_money(id) + amn)
	if(balance >= bankfees)
		balance -= bankfees
	else
		cs_set_user_money(id,cs_get_user_money(id) - bankfees)	
	set_balance(id,balance)
	if(bankfees > 0)
	{
		if(client)
			client_print(id,print_chat,"Banka Giderleri Icin $%d odediniz.",bankfees)
		else
			console_print(id,"Banka Giderleri Icin $%d odediniz.",bankfees)
	}
	bankfees += get_cvar_num("bank_fees_increase")
	if(client)
		client_print(id,print_chat,"Banka Hesabinizdan $%d para cektiniz. Simdi $%d Paraniz Var.",amn,balance)
	else
		console_print(id,"Banka Hesabinizdan $%d para cektiniz. Simdi $%d Paraniz Var.",amn,balance)
	return PLUGIN_HANDLED
}

public bank_deposit(id)
{
	new client = 0
	if(read_argc() > 2)
		client = 1
	if(!check_use(id,client)) return PLUGIN_HANDLED
	new damounts[9],damount,curmoney
	read_args(damounts,8)
	damount = str_to_num(damounts)
	if(damount <= 0) return PLUGIN_HANDLED
	curmoney = cs_get_user_money(id)
	if(damount > curmoney)
	{
		if(client)
			client_print(id,print_chat,"Okadar paraniz yok.")
		else
			console_print(id,"Okadar paraniz yok.")
		return PLUGIN_HANDLED
	}
	new balance = get_balance(id)
	if(balance == -1)
	{
		if(client)
			client_print(id,print_chat,"Bir Banka Hesabiniz Bulunmamaktadir.")
		else
			console_print(id,"Bir Banka Hesabiniz Bulunmamaktadir.")
		return PLUGIN_HANDLED
	}
	balance += damount
	set_balance(id,balance)
	cs_set_user_money(id,curmoney - damount)
	if(client)
		client_print(id,print_chat,"Banka Hesabiniza $%d yatirdiniz. Simdi $%d Paraniz Var.",damount,balance)
	else
		console_print(id,"Banka Hesabiniza $%d yatirdiniz. Simdi $%d Paraniz Var.",damount,balance)
	return PLUGIN_HANDLED
}
Link:
Linklerini gizle
Linki Kopyala
Başa dön
Kullanıcı avatarı

ByBuLuT ☪
Mesajlar: 2368
Kayıt: Sal Oca 26, 2016 3:54 pm
Konum: Samsun
Clan İsmi: -
İletişim:
İletişim ByBuLuT ☪

Amx Bank

Mesaj gönderen ByBuLuT ☪ »

sorunsuz calisiyormu def oyun dolari icin bankami bu verileri nereye kaydediyor
Link:
Linklerini gizle
Linki Kopyala
Başa dön
Kullanıcı avatarı

ByBuLuT ☪
Mesajlar: 2368
Kayıt: Sal Oca 26, 2016 3:54 pm
Konum: Samsun
Clan İsmi: -
İletişim:
İletişim ByBuLuT ☪

Amx Bank

Mesaj gönderen ByBuLuT ☪ »

bankayı olusturunca direk olusturuyo nickede kaydetmiyo eklentiyi kullanmak ıstıyorum ancak tam anlamadım
Link:
Linklerini gizle
Linki Kopyala
Başa dön
Kullanıcı avatarı

jottABey
Mesajlar: 951
Kayıt: Sal Şub 28, 2017 5:22 pm
Konum: Ankara
Server Ip/DNS: Cs42.CsDuragi.COM
Clan İsmi: DayilaR JB
İletişim:
İletişim jottABey

Amx Bank

Mesaj gönderen jottABey »

Bazı pluginler amx_ den çalışıyor yüklerken herhangi bir hata aldınmı ?
Link:
Linklerini gizle
Linki Kopyala
Başa dön
Kullanıcı avatarı

ByBuLuT ☪
Mesajlar: 2368
Kayıt: Sal Oca 26, 2016 3:54 pm
Konum: Samsun
Clan İsmi: -
İletişim:
İletişim ByBuLuT ☪

Amx Bank

Mesaj gönderen ByBuLuT ☪ »

sorunsuz yukledım herseyi normal calısıyor ancak kaydettigi yeri bulamadım ve guvenligi nasıl sagladıgını anlamadım ipye kaydediyosa modem resleyince felan ip degismiyor mu tam cozemedim guvenilirligini
Link:
Linklerini gizle
Linki Kopyala
Başa dön

Konu Sahibi
godlike
Mesajlar: 35
Kayıt: Çrş Şub 01, 2017 8:39 pm

Amx Bank

Mesaj gönderen godlike »

Teşekkür ederim PaZee eline sağlık. Bu arada türkçe kendi çevirim arkadaşlar :)

Yükerken bu hatayı aldım normalmidir?

//cstrike/addons/amxmodx/scripting/amx_bank.sma(32 -- 33) : error 001: expected token: ",", but found "-identifier-"
//cstrike/addons/amxmodx/scripting/amx_bank.sma(184) : warning 225: unreachable code
//cstrike/addons/amxmodx/scripting/amx_bank.sma(604) : warning 233: symbol "client_disconnect" is marked as deprecated: Use client_disconnected() instead.

1 Error.
Could not locate output file /cstrike/addons/amxmodx/plugins/amx_bank.amx (compile failed).
En son godlike tarafından Prş Mar 02, 2017 3:05 pm tarihinde düzenlendi, toplamda 1 kere düzenlendi.
Link:
Linklerini gizle
Linki Kopyala
Başa dön
Kullanıcı avatarı

ByBuLuT ☪
Mesajlar: 2368
Kayıt: Sal Oca 26, 2016 3:54 pm
Konum: Samsun
Clan İsmi: -
İletişim:
İletişim ByBuLuT ☪

Amx Bank

Mesaj gönderen ByBuLuT ☪ »

@godlike nereye kaydediyo hesapları ve guvenlimi cozemedım eklentiyi
Link:
Linklerini gizle
Linki Kopyala
Başa dön
Cevapla

“Cs 1.6 Eklenti İstekleri” sayfasına dön