Admine özel weapon menü istek

[0nurd0gann]

Merhabalar, ben adminler için el başladığında şöyle bir menü çıkmasını istiyorum;
[BLOODY] HIZLI SILAH MENUSU
1- M4a1 , deagle, hegrenede, armor, kit
2- ak47, deagle, hegrenede, armor, kit
3- Awp, deagle, hegrenede, armor, kit
Ve mümkünse ilk 3 el çıkmayacak şekilde yapabilen olursa sevinirim teşekkürler.

[Erhan1232YARDIM]

eklenti-istekleri/admin-silah-menu-t22210.html


Işine yarar mi ?

[0nurd0gann]

hayır bu olmaz

[Jess]

Kod: Tümünü seç

#include <amxmodx>
#include <reapi>

#define PLUGIN "Tur Basi Yetkiliye Ozel Silah Menusu"
#define VERSION "1.0"
#define AUTHOR "Jess"

#define ACCESS_FLAG ADMIN_BAN

public plugin_init() {

       register_plugin(PLUGIN, VERSION, AUTHOR)

       register_logevent("Event_RoundStart", 2, "1=Round_Start")
}

public Event_RoundStart() {

       if(get_member_game(m_iNumCTWins) + get_member_game(m_iNumTerroristWins) > 3)
       {
             for(new Id = 1; Id <= get_member_game(m_nMaxPlayers); Id++)
             {
                   if(is_user_connected(Id) && is_user_alive(Id) && get_user_flags(Id) & ACCESS_FLAG)
                   {
                        Admin_Weapon_Menu(Id);
                   }
             }               
       }
}

public Admin_Weapon_Menu(Id) {

       if(!is_user_connected(Id) || !is_user_alive(Id))
             return PLUGIN_HANDLED;

       new Menu = menu_create("\r [BLOODY] \y HIZLI SILAH MENUSU", "Give_Weapons")

       menu_additem(Menu, "\w M4A1 + Deagle + El Bombasi + Yelek + Kit", "1")
       menu_additem(Menu, "\w AK-47 + Deagle + El Bombasi + Yelek + Kit", "2")
       menu_additem(Menu, "\w AWP + Deagle + El Bombasi + Yelek + Kit", "3")

       menu_setprop(Menu, MPROP_EXITNAME, "Silah Menusunu Kullanmak Istemiyorum")
       menu_display(Id, Menu)

       return PLUGIN_CONTINUE;
}

public Give_Weapons(Id, Menu, Item) {

       if(Item == MENU_EXIT)
       {
             menu_destroy(Menu)
             return PLUGIN_HANDLED;
       }

       new Data[6], Access, Callback;
       menu_item_getinfo(Menu, Item, Access, Data, charsmax(Data), _, _, Callback)

       new Options = str_to_num(Data);
 
       switch(Options)
       {
             case 1:
             {
                  rg_give_item(Id, "weapon_m4a1")
                  rg_set_user_bpammo(Id, WEAPON_M4A1, 200)

                  rg_give_item(Id, "weapon_deagle")
                  rg_set_user_bpammo(Id, WEAPON_DEAGLE, 84)

                  rg_give_item(Id, "weapon_hegrenade")

                  rg_set_user_armor(Id, 100, ARMOR_KEVLAR)

                  rg_give_defusekit(Id)
             }

             case 2:
             {
                  rg_give_item(Id, "weapon_ak47")
                  rg_set_user_bpammo(Id, WEAPON_AK47, 200)

                  rg_give_item(Id, "weapon_deagle")
                  rg_set_user_bpammo(Id, WEAPON_DEAGLE, 84)

                  rg_give_item(Id, "weapon_hegrenade")

                  rg_set_user_armor(Id, 100, ARMOR_KEVLAR)

                  rg_give_defusekit(Id)
             }
 
             case 3:
             {
                  rg_give_item(Id, "weapon_awp")
                  rg_set_user_bpammo(Id, WEAPON_AWP, 90)

                  rg_give_item(Id, "weapon_deagle")
                  rg_set_user_bpammo(Id, WEAPON_DEAGLE, 84)

                  rg_give_item(Id, "weapon_hegrenade")

                  rg_set_user_armor(Id, 100, ARMOR_KEVLAR)

                  rg_give_defusekit(Id)
             }
       }
       
       return PLUGIN_CONTINUE;
}

Test ettiğim kadarıyla sorunsuz çalışmakta, sadece ban yetkisi olan yetkililere gelecek şekilde ayarladım menüyü. Sorun olursa bildirirsin