Eklenti küçük edit

[heaveNN]

Dener misin?

Kod: Tümünü seç

#include <amxmodx>
#include <reapi>

new bool:g_blIsPlayerConnectedAndAlive[MAX_CLIENTS + 1];
new g_iFrames[MAX_CLIENTS + 1];
new g_iCvar;

public plugin_init() {
    register_plugin("FPS Sinir", "0.0.1", "Schwarper");

    RegisterHookChain(RG_CBasePlayer_Spawn, "@CBasePlayer_Spawn_Post", .post = true);
    RegisterHookChain(RG_CBasePlayer_Killed, "@CBasePlayer_Killed_Post", .post = true);
    RegisterHookChain(RG_CBasePlayer_PreThink, "@CBasePlayer_PreThink_Pre", .post = false);

    bind_pcvar_num(create_cvar("fps_sinir", "240"), g_iCvar);
}

public client_disconnected(pPlayer) {
    g_blIsPlayerConnectedAndAlive[pPlayer] = false;
    remove_task(pPlayer);
}

@CBasePlayer_Spawn_Post(const pPlayer) {
    if(get_member(pPlayer, m_bJustConnected)) {
        client_cmd(pPlayer, "fps_max 200;");
	    client_cmd(pPlayer, "fps_modem 200;");
        return;
    }

    g_iFrames[pPlayer] = 0;
    g_blIsPlayerConnectedAndAlive[pPlayer] = true;
    set_task(1.0, "@CheckFpsPerSec", pPlayer, .flags = "b");
}

@CBasePlayer_Killed_Post(const pVictim) {
    g_blIsPlayerConnectedAndAlive[pVictim] = false;
    remove_task(pPlayer);
}

@CBasePlayer_PreThink_Pre(const pPlayer) {
    if(!g_blIsPlayerConnectedAndAlive[pPlayer]) {
        return;
    }

    g_iFrames[pPlayer]++;
}

@CheckFpsPerSec(const pPlayer) {
    if(g_iFrames[pPlayer] >= g_iCvar) {
        set_task(3.0, "@UnFreeze", pPlayer);
        set_entvar(pPlayer, var_flags, get_entvar(pPlayer, var_flags) | FL_FROZEN);

        client_print_color(pPlayer, pPlayer, "^4Fps Siniri: ^3%i^1. ^4Fps sinirini gectigin icin 3 saniye donduruldun.", g_iCvar);
    }

    g_iFrames[pPlayer] = 0;
}

@UnFreeze(const pPlayer) {
    set_entvar(pPlayer, var_flags, get_entvar(pPlayer, var_flags) & ~FL_FROZEN);
    client_print_color(pPlayer, pPlayer, "^4 3 ^1saniyelik cezan bitti. ^3Lutfen fps sinirini gecmeyin. ^4Fps siniri^1: ^3%i", g_iCvar);
}

Kod: Tümünü seç

ze_fps_siniri.sma(26) : warning 217: loose indentation
ze_fps_siniri.sma(27) : warning 217: loose indentation
ze_fps_siniri.sma(37) : error 017: undefined symbol "pPlayer"
ze_fps_siniri.sma(37) : error 088: number of arguments does not match definition

2 Errors.
Could not locate output file ze_fps_siniri.amx (compile failed).

Böyle bir hata verdi.

Kod: Tümünü seç

#include <amxmodx>
#include <reapi>

new bool:g_blIsPlayerConnectedAndAlive[MAX_CLIENTS + 1];
new g_iFrames[MAX_CLIENTS + 1];
new g_iCvar;

public plugin_init() {
    register_plugin("FPS Sinir", "0.0.1", "Schwarper");

    RegisterHookChain(RG_CBasePlayer_Spawn, "@CBasePlayer_Spawn_Post", .post = true);
    RegisterHookChain(RG_CBasePlayer_Killed, "@CBasePlayer_Killed_Post", .post = true);
    RegisterHookChain(RG_CBasePlayer_PreThink, "@CBasePlayer_PreThink_Pre", .post = false);

    bind_pcvar_num(create_cvar("fps_sinir", "240"), g_iCvar);
}

public client_disconnected(pPlayer) {
    g_blIsPlayerConnectedAndAlive[pPlayer] = false;
    remove_task(pPlayer);
}

@CBasePlayer_Spawn_Post(const pPlayer) {
	if(get_member(pPlayer, m_bJustConnected)) {
		client_cmd(pPlayer, "fps_max 200;");
		client_cmd(pPlayer, "fps_modem 200;");
		return;
	}
	
	g_iFrames[pPlayer] = 0;
	g_blIsPlayerConnectedAndAlive[pPlayer] = true;
	set_task(1.0, "@CheckFpsPerSec", pPlayer, .flags = "b");
}

@CBasePlayer_Killed_Post(const pVictim) {
    g_blIsPlayerConnectedAndAlive[pVictim] = false;
    remove_task(pVictim);
}

@CBasePlayer_PreThink_Pre(const pPlayer) {
    if(!g_blIsPlayerConnectedAndAlive[pPlayer]) {
        return;
    }

    g_iFrames[pPlayer]++;
}

@CheckFpsPerSec(const pPlayer) {
    if(g_iFrames[pPlayer] >= g_iCvar) {
        set_task(3.0, "@UnFreeze", pPlayer);
        set_entvar(pPlayer, var_flags, get_entvar(pPlayer, var_flags) | FL_FROZEN);

        client_print_color(pPlayer, pPlayer, "^4Fps Siniri: ^3%i^1. ^4Fps sinirini gectigin icin 3 saniye donduruldun.", g_iCvar);
    }

    g_iFrames[pPlayer] = 0;
}

@UnFreeze(const pPlayer) {
    set_entvar(pPlayer, var_flags, get_entvar(pPlayer, var_flags) & ~FL_FROZEN);
    client_print_color(pPlayer, pPlayer, "^4 3 ^1saniyelik cezan bitti. ^3Lutfen fps sinirini gecmeyin. ^4Fps siniri^1: ^3%i", g_iCvar);
}

[Colditz]

Böyle bir hata verdi.

Düzelttim dener misin?