Admin Özel Şapka

[DehaBihan57]

cs 1.6 Jailbreak serverime şapma modeli eklemek istiyorum ama sadece adminlere özel bunu nasıl yapabilirim? eski panelde kolaydı ama bu panelde yapamadım. saygılarımla

[YeKTaBEYy]

@DehaBihan57 yükliceğin admin şapka modelini panelden models klasörüne yükle ilk önce daha sonra bu eklentiyi aç modelin adı neyse eklentinin içine şu satıra yaz daha sonra panele yükle eklentiyi plugins.ini ' ye yaz haritayı değiştir olur bu arada KİCK yetkisine ayarlı kick yetkisi olan adminlerde gözükür

Kod: Tümünü seç

"models/vforvendetta.mdl";

[halilsen16]

1el kendi yüklediğim gözüküyor diğer el orjinal olan çözemedim ben bu konuyu

[ulyoS]

1el kendi yüklediğim gözüküyor diğer el orjinal olan çözemedim ben bu konuyu

Kod: Tümünü seç

#include <amxmodx>
#include <engine>

	//Eğer ki admin_head modelini kullanmaya devam edecekseniz bir alt satırdaki #define SADECE_PRO_SAPKASI nın başında // olmayacak,
	//Ama eğer ki pelerin modeli yada abuk sabuk bir model için ayarlama yapacaksanız aşağıdaki #define SADECE_PRO_SAPKASI nın başında // olmalı.
	//Bunun sebebi bu eklentinin admin_head.mdl modeline uyumlu yazılması.

// #define SADECE_PRO_SAPKASI

//Eklenti Hakkında -> Admin şapkasının skin değişimi için oyuncu doğmasını algılayan bir yer lazım, hamsandwich.
#if defined SADECE_PRO_SAPKASI
#include <hamsandwich>
#endif

//Eklenti Hakkında -> 1.8.3 uyumunu bu şekilde sağladım, eğer ki AmxModx sürümü 1.8.3'ün altında ise disconnected kısmını disconnect olarak değiştirecek.
#if AMXX_VERSION_NUM < 183
	#define client_disconnected client_disconnect
#endif	




	//Admin yetkisi, kick olarak ayarladım ben, gerekirse değiştirirsiniz.
#define YETKI ADMIN_KICK


	//Şapka modelinin yolu, eğer bu modeli değiştirecekseniz SADECE_PRO_SAPKASI ayarından çıkartınız. Satır 4'ü okuyunuz.
new const SAPKA_YOLU[] = "models/vforvendetta.mdl";

new Ent[33];

public plugin_init() {
	register_plugin("Admin Sapkasi", "1.0", "CSmiLeFaCe");
	#if defined SADECE_PRO_SAPKASI
	RegisterHam(Ham_Spawn, "player", "Spawn", true);
	//Eklenti Hakkında -> Spawn kullanmamın sebebi eğer ki model değişikliği olur ise şapkanında ona göre değişmesi.
	#endif
}
#if defined SADECE_PRO_SAPKASI
public Spawn(id) {
	if(is_valid_ent(Ent[id]) && is_user_connected(id) && is_user_alive(id)) {
		new modelID = get_model_id(id)
		entity_set_int(Ent[id], EV_INT_body, modelID);
	}
}
#endif
Kontrol(const id) {
	if(Ent[id] && is_valid_ent(Ent[id])) {
		entity_set_int(Ent[id], EV_INT_flags, FL_KILLME);
		entity_set_float(Ent[id], EV_FL_nextthink, get_gametime());
		Ent[id] = 0;
	}
}
public client_putinserver(id) {
	if(!(get_user_flags(id) & YETKI)) {
		return;
	}
	Kontrol(id);
	if((Ent[id] = create_entity("info_target"))) {
		entity_set_string(Ent[id], EV_SZ_classname, "sapka");
		entity_set_model(Ent[id], SAPKA_YOLU);
		entity_set_int(Ent[id], EV_INT_movetype, MOVETYPE_FOLLOW);
		entity_set_edict(Ent[id], EV_ENT_aiment, id);
	}
}

public client_disconnected(id) {
	Kontrol(id);
}

public plugin_precache() {
	precache_model(SAPKA_YOLU);
	#if defined SADECE_PRO_SAPKASI
	force_unmodified(force_model_samebounds,{0,0,0},{0,0,0},"models/player/gign/gign.mdl");
	force_unmodified(force_model_samebounds,{0,0,0},{0,0,0},"models/player/gsg9/gsg9.mdl");
	force_unmodified(force_model_samebounds,{0,0,0},{0,0,0},"models/player/sas/sas.mdl");
	force_unmodified(force_model_samebounds,{0,0,0},{0,0,0},"models/player/urban/urban.mdl");
	force_unmodified(force_model_samebounds,{0,0,0},{0,0,0},"models/player/vip/vip.mdl");
	force_unmodified(force_model_samebounds,{0,0,0},{0,0,0},"models/player/arctic/arctic.mdl");
	force_unmodified(force_model_samebounds,{0,0,0},{0,0,0},"models/player/guerilla/guerilla.mdl");
	force_unmodified(force_model_samebounds,{0,0,0},{0,0,0},"models/player/leet/leet.mdl");
	force_unmodified(force_model_samebounds,{0,0,0},{0,0,0},"models/player/terror/terror.mdl");
	//Buraları bilmiyorum neden yazılmış, KaLoSZyFeR yazmış, kullanmaz isek ayıp olur.
	#endif
}
#if defined SADECE_PRO_SAPKASI
//Alt kısım adminmark eklentisinden hazır olarak alınmıştır. 
//Written by KaLoSZyFeR for adminmark model file.
new modelname[9][] ={
	"gign",
	"gsg9",
	"sas",
	"urban",
	"vip",
	"arctic",
	"guerilla",
	"leet",
	"terror"
}
public get_model_id(id)
{
	new modelStr[32], iNum=32, modelID
	get_user_info(id,"model",modelStr,iNum)
	
	for(new i = 0; i < 9; i++)
	{
		if (equali (modelStr, modelname[i]) )
		{
			modelID = i
		}
	}	
	return modelID
}
#endif

Dener misin?

[halilsen16]

eyw brom çalıştı sana maaş bağlamaları lazım

[ulyoS]

eyw brom çalıştı sana maaş bağlamaları lazım

yok dostum ne demek, bir sıkıntı olduğunda etiket atman yeterli bilgim var ise çözmeye çalışırım yoksa da öğrenmiş oluruz nasıl yapıldığını

[halilsen16]

bide şöyle bi sıkıntı var bende Biohazard mod da enfeksiyon yayıldıktan sonra admin modeller gidiyor normaline dönüyor

kullandığım plugin bu
.sma

koz_admin_mod.sma

[ulyoS]

bide şöyle bi sıkıntı var bende Biohazard mod da enfeksiyon yayıldıktan sonra admin modeller gidiyor normaline dönüyor

kullandığım plugin bu
.sma
koz_admin_mod.sma

Enfeksiyon yayılması kaç saniye sürüyor? Düşüncem şu şekilde, büyük ihtimal enfeksiyon yayıldıktan hemen sonra çoğu şeyi eski haline getiriyor ana eklentin. Bu eklentiyi ana eklentinin en üstüne yazmayı dene, olmadı eklenti içine task açar el başladıktan belli süre sonra işleve girmesini sağlarız.

[halilsen16]

amxx i en başa kaydettim fayda etmedi enfeksiyor 15 saniye sonra yayılıyor

[ulyoS]

amxx i en başa kaydettim fayda etmedi enfeksiyor 15 saniye sonra yayılıyor

Özel değilse atabilir misiniz ana eklentiyi?