Oyuniçi PM Gönderme Eklentisi [İstek]

[Gozyasi`]

Selam. Oyuniçinden PM yani özel mesaj göndermeyi sağlayan eklentiye ihtiyacım var. Forumda aradım ama bulamadım bir türlü. Varsa konusu link bırakmanız yeterli.

(Eklenti Taha'nın sunucuda var, ss leride oradan aldım) ;

[Captan Price]

amx_psay (private say) bu komutun geliştirilmiş hali. PM için amx_psay komutunu kullanabilirsin.

[Gozyasi`]

Oyuncuların menü üzerinden birbirlerine pm atabilmeleri için eklenti şart.

[F.T.H]

https://forums.alliedmods.net/showthread.php?t=188906

[Gozyasi`]

Aradığım eklentiyi buldum ama bu da 30 a yakın hata veriyor. Çok ilginç.

Kod: Tümünü seç

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <amxmisc>
#include <colorchat>

#define PLUGIN "PM Sistemi"
#define VERSION "1.0"
#define AUTHOR "akcaliberkk"

#define ADMIN_FLAG ADMIN_BAN

new SonMesajAtan[33][32];
new SonMesajAtilan[33][32];
new HedefID[33];
new bool:MessageModeBySystem;
new pAdminRead;
new pOtoBind;

new const CUSTOM_SOUND[] = "buttons/blip1.wav";

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR)
	
	pAdminRead = register_cvar("pm_admin_read","1")
	pOtoBind = register_cvar("pm_otobind","p")
	
	register_clcmd("say /pm","ShowMenu")
	register_clcmd("Mesajinizi Girin","ReceiveMessage")
}
public plugin_precache() {
	precache_sound(CUSTOM_SOUND);
}
public client_connect(id) {
	new PMKey[3];
	get_pcvar_string(pOtoBind,PMKey,2)
	if(PMKey[0] != 0) {
		client_cmd(id,"bind %s ^"say /pm^"",PMKey)
	}
}
public ShowMenu(id) {
	new menu = menu_create("\rOzel Mesaj:\y Metod Seciniz","menu_handler")
	
	if(SonMesajAtan[id][0] != 0) {
		menu_additem(menu,"Son Gelen Mesaji Cevapla","1")
	}
	if(SonMesajAtilan[id][0] != 0) {
		menu_additem(menu,"Son Mesaj Gonderilen Kisi","2")
	}
	if((SonMesajAtan[id][0] == 0) && (SonMesajAtilan[id][0] == 0) ) {
		OyuncuListele(id);
		menu_destroy(menu)
		return PLUGIN_HANDLED
	}
	else {
		menu_additem(menu,"Oyuncu Listele","3")
	}
	menu_setprop(menu,MPROP_EXIT,MEXIT_ALL)
	menu_display(id,menu,0)
	return PLUGIN_HANDLED
}
public menu_handler(id,menu,item) {	
	if(item == MENU_EXIT) {
		menu_destroy(menu)
		return PLUGIN_HANDLED
	}
	new data[6],name[32];
	new access,callback,tempid;
	menu_item_getinfo(menu,item,access,data,5,name,31,callback)
	switch(str_to_num(data)) {
		case 1:{
			tempid = find_player("bhl",SonMesajAtan[id]);
			if(!tempid) {
				ColorChat(id,GREEN,"[OZEL MESAJ] ^3Ilgili Oyuncu Serverdan Ayrildi")
			}
			else {
				HedefID[id] = tempid;
				MessageModeBySystem = true;
				client_cmd(id,"messagemode ^"Mesajinizi Girin^"")
			}
		}
		case 2:{
			tempid = find_player("bhl",SonMesajAtilan[id]);
			if(!is_user_connected(tempid)) {
				ColorChat(id,GREEN,"[OZEL MESAJ] ^3Ilgili Oyuncu Serverdan Ayrildi")
			}
			else {
				HedefID[id] = tempid;
				MessageModeBySystem = true;
				client_cmd(id,"messagemode ^"Mesajinizi Girin^"")
			}
		}
		case 3:{
			OyuncuListele(id)
		}
	}
	menu_destroy(menu)
	return PLUGIN_HANDLED
}
public OyuncuListele(id) {
	new plmenu = menu_create("\rOzel Mesaj:\y Oyuncu Seciniz","plmenu_handler")
	
	new players[32],inum,tempid;
	new name[32],szID[10];
	
	get_players(players,inum)
	for(new i;i<inum;i++) {
		tempid = players[i];
		
		if(tempid == id) continue;
		
		get_user_name(tempid,name,31)
		num_to_str(tempid,szID,9)
		
		menu_additem(plmenu,name,szID)
	}
	menu_setprop(plmenu,MPROP_EXIT,MEXIT_ALL)
	menu_display(id,plmenu,0)
	return PLUGIN_HANDLED
}
public plmenu_handler(id,menu,item) {
	if(item == MENU_EXIT) {
		menu_destroy(menu)
		return PLUGIN_HANDLED
	}
	new data[10],name[32];
	new access,callback;
	menu_item_getinfo(menu,item,access,data,9,name,31,callback)
	new Uid = str_to_num(data);
	if(is_user_connected(Uid)) {
		HedefID[id] = Uid;
		MessageModeBySystem = true;
		client_cmd(id,"messagemode ^"Mesajinizi Girin^"")
	}
	else {
		ColorChat(id,GREEN,"[OZEL MESAJ] ^3Ilgili Oyuncu Serverdan Ayrildi")
		OyuncuListele(id);
	}
	menu_destroy(menu)
	return PLUGIN_HANDLED
}
public ReceiveMessage(id) {
	if(!MessageModeBySystem) {
		console_print(id,"Gecersiz Istek")
		return PLUGIN_HANDLED
	}
	MessageModeBySystem = false;
	
	new szMSG[248];
	read_args(szMSG,charsmax(szMSG))
	remove_quotes(szMSG)
	new part1[6],part2[248];
	parse(szMSG,part1,5,part2,247);
	copy(szMSG,247,part2)
	remove_quotes(szMSG);
	
	if(szMSG[0] == 0) {
		ColorChat(id,GREEN,"[OZEL MESAJ] ^3Mesaj Kismi Bos Birakilamaz !")
		MessageModeBySystem = true;
		client_cmd(id,"messagemode ^"Mesajinizi Girin^"")
		return PLUGIN_HANDLED
	}
	
	new sender_name[32],receiver_name[32]
	get_user_name(id,sender_name,31)
	get_user_name(HedefID[id],receiver_name,31)
	
	ColorChat(HedefID[id],GREEN,"[OZEL MESAJ] ^3%s: ^4%s",sender_name,szMSG)
	ColorChat(id,GREEN,"[OZEL MESAJ] ^3%s: ^4%s",sender_name,szMSG)
	log_amx("[OZEL MESAJ] Gonderen: %s Alan: %s Mesaj: %s",sender_name,receiver_name,szMSG)
	
	new players[32],inum;
	get_players(players,inum)
	for(new i;i<inum;i++) {
		if(players[i] == id) continue
		if(players[i] == HedefID[id]) continue
		if(access(players[i],ADMIN_FLAG) && get_pcvar_num(pAdminRead)) {
			ColorChat(players[i],GREEN,"[^3%s ^4-> ^3%s] ^4Mesaj: ^1%s",sender_name,receiver_name,szMSG)
		}
	}
	
	client_cmd(HedefID[id] , "spk %s" , CUSTOM_SOUND);
	client_print(HedefID[id], print_center,"Ozel Mesaj Aldiniz")
	
	copy(SonMesajAtan[HedefID[id]],31,sender_name)
	copy(SonMesajAtilan[id],31,receiver_name)
	
	return PLUGIN_HANDLED
	
}
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1055\\ f0\\ fs16 \n\\ par }
*/

[F.T.H]

Aradığım eklentiyi buldum ama bu da 30 a yakın hata veriyor. Çok ilginç.

Ne gibi bir hata veriyor panele yüklendiğinde bende sıkıntı yok

[Necati Doğan]

Colorchat hata verir büyük ihtimal. Colorchat'ı client_print_color 'a çevirebilirsin.

[Gozyasi`]

@tekvatan zannedersem sublime text de bug oluştu. Yukarıdaki eklentiyi sma şeklinde atarmısın bana?

[F.T.H]

@tekvatan zannedersem sublime text de bug oluştu. Yukarıdaki eklentiyi sma şeklinde atarmısın bana?

[Gozyasi`]

Sorun nerede olabilir kardeşler ;