Silah İnceleme Eklentisi Bakarmısınız

[faruk19005]

Şimdi Bir Tane Silah İnceleme Eklentisi Var Ama 3 Tane Silaha Oluyor O 3 Tane Silahıda Say Komutuyla Alabılıyorsun ve F Tuşuna Basıp İnceliyorsun Mesela /m3 vs. Pluginden Anlarsınız Zaten . Benim İsteğim Bu Pluginin Tüm Silahlara F Tuşuna Ayarlanması Yapabilecek Arkadaş Teşekkür Ediyorum Bundan Zaten Tek Ben Faydalanmıcam

Credit-SkumTomteN.zip

[faruk19005]

@Yek'-ta
@redarmygaming

[Taha Demirbaş]

Icerige suan bakamiyorum. Fakat mdl dosyasi varmidir o silahlarin

[faruk19005]

@redarmygaming Hepsi Dosyanın İçinde Var

[Fatih ~ EjderYa]

@faruk19005 Eğer Silah Modellerinizde Pluginin Göndermiş Olduğu Komutu karşılayacak bir satır yoksa. Bunu gerçekleştiremezsiniz.
Bunun için istediğiniz .mdl dosyasını ve .sma ' yı atmalısınız ki ikisini bir arada buluşturalım

[faruk19005]

İstediğim sma yok benim istediğim /m3 yazıp aldıgın model de ınceleme yapabılıyorsun ben bunun kaldırılıp yenı models yerlerı açılmasını[ben doldurum]ve her sılahda ıncelenmesını istiyorum mümkün değilmidir yani

[Fatih ~ EjderYa]

şimdi .sma ' yı görmeden bir şey diyemem. Silah modelinden bir index ' i kullanarak mı model döndürüyor. Yoksa Bulunduğunuz koordinata silahın _P veya _W hallerini göndererek mi işlem uyguluyor anlayamadım.

Eğer _P veya _W halleri ise her silahda olması mümkün.
Eğer diğer seçenek ise sadece pluginin desteklediği .mdl lerde olabilir.

[faruk19005]

animasyon vererek yapıyor p ve w halleriyle alkası yok

[faruk19005]

Kod: Tümünü seç

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>
#include <cstrike>
#include <fun>

#define PLUGIN "CS:GO Weapon Pack"
#define VERSION "1.2"
#define AUTHOR "Nani"

/* Flag for command to get weapon */
#define ADMIN_FLAG ADMIN_LEVEL_H

/* Here you can change the base weapon entity */
#define weapon_cz75 "weapon_mp5navy"
#define weapon_r8 "weapon_deagle"
#define weapon_tec9 "weapon_fiveseven"

/* Here you can change the base weapon id */
#define CSW_CZ75 CSW_MP5NAVY
#define CSW_R8 CSW_DEAGLE
#define CSW_TEC9 CSW_FIVESEVEN

/* Here you can change the weapon model */
#define V_MODEL_TEC9 "models/v_tec9.mdl"
#define V_MODEL_R8 "models/v_r8.mdl"
#define V_MODEL_CZ75 "models/v_cz75.mdl"

/* Here you can change when the anim will be removed */
#define ANIM_TIME_CZ75 4.0
#define ANIM_TIME_R8 3.5
#define ANIM_TIME_TEC9 2.0

/* Here you can change the weapon anim */
#define ANIM_IDLE 0
#define ANIM_INSPECT 6

/* Do not touch */
#define TASK_PLAYANIM 2049
#define TASK_STOPANIM 2050

/* pData Offsets */
#define WEAP_LINUX_XTRA_OFF 4
#define OFFSET_WEAPONOWNER 41
#define OFFSET_ACTIVE_ITEM 373

// Entity names
new const WEAPONENTNAMES[][] = { "", "weapon_p228", "", "weapon_scout", "weapon_hegrenade", "weapon_xm1014", "weapon_c4", "weapon_mac10",
	"weapon_aug", "weapon_smokegrenade", "weapon_elite", "weapon_fiveseven", "weapon_ump45", "weapon_sg550",
	"weapon_galil", "weapon_famas", "weapon_usp", "weapon_glock18", "weapon_awp", "weapon_mp5navy", "weapon_m249",
	"weapon_m3", "weapon_m4a1", "weapon_tmp", "weapon_g3sg1", "weapon_flashbang", "weapon_deagle", "weapon_sg552",
"weapon_ak47", "weapon_knife", "weapon_p90" }

new bool:g_bInAnimation[33] = false, bool:g_bCancelAnimation[33] = false;

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR)
	
	register_forward(FM_CmdStart, "fw_CmdStart")

	register_clcmd("say /cz75", "Get_CZ75")
	register_clcmd("say /r8", "Get_R8")
	register_clcmd("say /tec9", "Get_TEC9")
	
	for (new i = 1; i < sizeof(WEAPONENTNAMES); i++)
	{
		if (WEAPONENTNAMES [i][0]) 
		{
			RegisterHam(Ham_Item_Deploy, WEAPONENTNAMES[i], "fw_Item_Deploy_Post", 1);
		}
	}
}

public plugin_precache()
{
	precache_model(V_MODEL_TEC9)
	precache_model(V_MODEL_R8)
	precache_model(V_MODEL_CZ75)
}

public client_disconnect(iPlayer)
{
	remove_task(iPlayer+TASK_PLAYANIM)
	remove_task(iPlayer+TASK_STOPANIM)
	
	g_bInAnimation[iPlayer] = false;
	g_bCancelAnimation[iPlayer] = false;
}

/* Admin can get weapons for free here, simply for testing the weapons */
public Get_CZ75(iPlayer)
{
	if(!(get_user_flags(iPlayer) & ADMIN_FLAG))
	{
		client_print(iPlayer, print_chat, "Only admin can use this command...")
		return;
	}

	give_item(iPlayer, weapon_cz75)
	
	static Ent; Ent = fm_get_user_weapon_entity(iPlayer, CSW_CZ75)
	if(!pev_valid(Ent)) 
		return;
	
	cs_set_weapon_ammo(Ent, 30)
	cs_set_user_bpammo(iPlayer, CSW_CZ75, 120)
}

public Get_R8(iPlayer)
{
	if(!(get_user_flags(iPlayer) & ADMIN_FLAG))
	{
		client_print(iPlayer, print_chat, "Only admin can use this command...")
		return;
	}
	
	give_item(iPlayer, weapon_r8)
	
	static Ent; Ent = fm_get_user_weapon_entity(iPlayer, CSW_R8)
	if(!pev_valid(Ent)) 
		return;
	
	cs_set_weapon_ammo(Ent, 20)
	cs_set_user_bpammo(iPlayer, CSW_R8, 100)
}

public Get_TEC9(iPlayer)
{
	if(!(get_user_flags(iPlayer) & ADMIN_FLAG))
	{
		client_print(iPlayer, print_chat, "Only admin can use this command...")
		return;
	}
	
	give_item(iPlayer, weapon_tec9)
	
	static Ent; Ent = fm_get_user_weapon_entity(iPlayer, CSW_TEC9)
	if(!pev_valid(Ent)) 
		return;
	
	cs_set_weapon_ammo(Ent, 13)
	cs_set_user_bpammo(iPlayer, CSW_TEC9, 52)
}

public fw_CmdStart(iPlayer, uc_handle, seed)
{
	if (!is_user_alive(iPlayer))
		return FMRES_IGNORED;	
	
	new iWeaponID = get_user_weapon(iPlayer);
	if(iWeaponID == CSW_CZ75 || iWeaponID == CSW_R8 || iWeaponID == CSW_TEC9)
	{
		new UseButton = get_uc(uc_handle, UC_Buttons)
		
		/* Player presses other buttons, we remove anim+task */
		if(g_bInAnimation[iPlayer])
		{
			if(UseButton & IN_RELOAD || UseButton & IN_ATTACK || UseButton & IN_ATTACK2)
			{
				g_bCancelAnimation[iPlayer] = true;
				
				set_task(0.01, "Task_StopAnimation", (TASK_STOPANIM + iPlayer))
			}
		}
	}
	return FMRES_IGNORED;
}

public client_impulse(iPlayer, iImpulse)
{
	if(iImpulse != 100)
		return PLUGIN_HANDLED_MAIN;
	if(g_bInAnimation[iPlayer])
		return PLUGIN_HANDLED_MAIN;
	
	new iWeaponID = get_user_weapon(iPlayer)

	if(iWeaponID == CSW_CZ75 || iWeaponID == CSW_R8 || iWeaponID == CSW_TEC9)
	{
		set_task(0.01, "Task_PlayAnimation", (TASK_PLAYANIM + iPlayer))
	}
	
	return PLUGIN_HANDLED_MAIN;
}

public Task_PlayAnimation(iPlayer) 
{
	iPlayer -= TASK_PLAYANIM;
	
	client_print(0, print_center, "Inspecting Weapon")
	
	Set_WeaponAnim(iPlayer, ANIM_INSPECT)
	
	g_bInAnimation[iPlayer] = true;
	
	/* Why stop it if its already stopped?, stupid! */
	if(!g_bCancelAnimation[iPlayer])
	{
		new Float:fAnimTime, iCSWID, iWeaponID = get_user_weapon(iPlayer);
		switch(iWeaponID)
		{
			case CSW_CZ75: 
			{
				iCSWID = CSW_CZ75;
				fAnimTime = ANIM_TIME_CZ75;
			}
			case CSW_R8: 
			{
				iCSWID = CSW_R8;
				fAnimTime = ANIM_TIME_R8;
			}
			case CSW_TEC9: 
			{
				iCSWID = CSW_TEC9;
				fAnimTime = ANIM_TIME_TEC9;
			}
		}
		
		Set_WeaponIdleTime(iPlayer, iCSWID, fAnimTime)
		Set_PlayerNextAttack(iPlayer, fAnimTime)
		
		set_task(fAnimTime, "Task_StopAnimation", (TASK_STOPANIM + iPlayer))
	}
}

public Task_StopAnimation(iPlayer)
{
	iPlayer -= TASK_STOPANIM;

	remove_task(iPlayer+TASK_PLAYANIM)
	remove_task(iPlayer+TASK_STOPANIM)
	
	g_bInAnimation[iPlayer] = false;
	g_bCancelAnimation[iPlayer] = false;
	
	Set_WeaponAnim(iPlayer, ANIM_IDLE)
	
	return PLUGIN_HANDLED;
}

public fw_Item_Deploy_Post(iEnt)
{
	if(pev_valid(iEnt) != 2)
		return;
	new iPlayer = get_pdata_cbase(iEnt, OFFSET_WEAPONOWNER, WEAP_LINUX_XTRA_OFF)
	if(get_pdata_cbase(iPlayer, OFFSET_ACTIVE_ITEM) != iEnt)
		return;
	
	new iWeaponID = cs_get_weapon_id(iEnt)
	
	switch(iWeaponID)
	{
		case CSW_CZ75: set_pev(iPlayer, pev_viewmodel2, V_MODEL_CZ75)
		case CSW_R8: set_pev(iPlayer, pev_viewmodel2, V_MODEL_R8)
		case CSW_TEC9: set_pev(iPlayer, pev_viewmodel2, V_MODEL_TEC9)
	}
}

stock Set_WeaponAnim(id, anim)
{
	set_pev(id, pev_weaponanim, anim)
	
	message_begin(MSG_ONE_UNRELIABLE, SVC_WEAPONANIM, {0, 0, 0}, id)
	write_byte(anim)
	write_byte(pev(id, pev_body))
	message_end()
}

stock fm_get_user_weapon_entity(id, wid = 0) 
{
	new weap = wid, clip, ammo;
	if (!weap && !(weap = get_user_weapon(id, clip, ammo)))
		return 0;
	
	new class[32];
	get_weaponname(weap, class, sizeof class - 1);

	return fm_find_ent_by_owner(-1, class, id);
}

stock fm_find_ent_by_owner(index, const classname[], owner, jghgtype = 0)
 {
	new strtype[11] = "classname", ent = index;
	switch (jghgtype) {
		case 1: strtype = "target";
		case 2: strtype = "targetname";
	}

	while ((ent = engfunc(EngFunc_FindEntityByString, ent, strtype, classname)) && pev(ent, pev_owner) != owner) {}

	return ent;
}

stock Set_WeaponIdleTime(id, WeaponId ,Float:TimeIdle)
{
	static entwpn; entwpn = fm_get_user_weapon_entity(id, WeaponId)
	if(!pev_valid(entwpn)) 
		return
		
	set_pdata_float(entwpn, 46, TimeIdle, 4)
	set_pdata_float(entwpn, 47, TimeIdle, 4)
	set_pdata_float(entwpn, 48, TimeIdle + 0.5, 4)
}

stock Set_PlayerNextAttack(id, Float:nexttime)
{
	if(pev_valid(id) == 2) set_pdata_float(id, 83, nexttime, 5)
}

[faruk19005]

#güncel