CSDuragi.COM Forum


https://forum.csduragi.com/

Yetkiver [istek]

https://forum.csduragi.com/viewtopic.php?t=18117

1. sayfa (Toplam 1 sayfa)

Yetkiver [istek]

Gönderilme zamanı: Cum Ağu 11, 2017 2:36 pm
gönderen By-Muhammed
arkadaşlar eline %100 çalışan yetkiver varmı

sadece slot 4 komut 1 yazıcak ?

Yetkiver [istek]

Gönderilme zamanı: Cum Ağu 11, 2017 2:39 pm
gönderen Taha Demirbaş
Forumda en gelismisi bulunmakta eklentilerde bulunmakta

Yetkiver [istek]

Gönderilme zamanı: Cum Ağu 11, 2017 2:42 pm
gönderen legolalp

Kod: Tümünü seç

#include <amxmodx>

// Slotun Baþýna Gelicek Tag
#define SlotTag "TAG | " 

//Komutcunun Baþýna Gelicek Tag
#define KomutcuTag "TAG | "

//Komutcu Sonuna Gelicek Taglar

#define Komutcu1Ver " [K-1]" 

// Slotun Sonuna Gelicek Taglar

#define Slot4Ver " [S-4]"

// Reklam Buraya Serverinizin Adini Yazabilirsiniz

#define Reklam "KLAN Gaming" 

new const file[] = "addons/amxmodx/configs/users.ini";

new 
bool:Komutcu1_Nick_Giris[33],
bool:Komutcu1_sfre_Giris[33],
bool:Slot4_Nick_Giris[33],
bool:Slot4_sfre_Giris[33],
pFlags4,
pFlags10,
g_szName[33][32];

public plugin_init() {

        // Slot Yetkileri
   pFlags4 = register_cvar("Slot4_Yetki","beijp") // Slot-4 Yetkileri  

        // Komutcu Yetkileri

   pFlags10 = register_cvar("Komutcu1_Yetki","bp") // Komutcu-1 Yetkileri 

   
   register_clcmd("say /yetkiver","YetkiVer")
   register_clcmd("Slot4_Nick","mSlot4_Nick")
   register_clcmd("Slot4_Sifre","mSlot4_Sifre")
   register_clcmd("Komutcu1_Nick","mKomutcu1_Nick")
   register_clcmd("Komutcu1_Sifre","mKomutcu1_Sifre")
}
public YetkiVer(id) 
{
   if(get_user_flags(id) & ADMIN_CFG)
        {
   new menu = menu_create("\rYetkili Ekle", "YetkiVer2")
   
   menu_additem(menu, "\rSlot-4 Yaz", "1", 0);
   menu_additem(menu, "\rKomutcu-1 Yaz", "2", 0);
   menu_additem(menu, "\rYetkili Sil", "3", 0);
   menu_additem(menu, "\rKullanim Klavuzu", "4", 0);
   menu_setprop(menu,MPROP_EXITNAME,"\rCikis");
   menu_display(id, menu, 0)
        }
}
public YetkiVer2(id, menu, item)
{
   if(item == MENU_EXIT)
   {
      menu_destroy(menu);
      return PLUGIN_HANDLED;
   }
   new Data[6], Name[32], Access, Callback
   menu_item_getinfo(menu, item, Access, Data, sizeof(Data) - 1, Name, sizeof(Name) - 1, Callback)
   new Key = str_to_num(Data)
   switch(Key)
   {
      case 1: {
         Slot4_Nick_Giris[id] = true;
         client_cmd(id,"messagemode Slot4_Nick")
         RenkliYazi(id,"!t[!g%s!t]!n: !tSlot-4 Nickini Giriniz!n.",Reklam)
      }
      case 2: {
         Komutcu1_Nick_Giris[id] = true;
         client_cmd(id,"messagemode Komutcu1_Nick")
         RenkliYazi(id,"!t[!g%s!t]!n: !tKomutcu-1 Nickini Giriniz!n.",Reklam)
      }
      case 3: {
         YetkiliSil(id)
      }
      case 4: {
         KullanimKlavuzu(id)
      }
   }
   menu_destroy(menu);
   return PLUGIN_HANDLED;
}
public KullanimKlavuzu(id)
{
   new menu = menu_create("\rKullanim Klavuzu", "KullanimKlavuzu2")

   menu_additem(menu, "\wKullanicinin Sadece Nickini Giriniz", "1", 0);
   menu_additem(menu, "\wYetkililer Icin Basina Gelicek Tag ", "1", 0);
   menu_additem(menu, "\wYetkililer Icin Sonuna Gelicek Tag", "1", 0);
   menu_additem(menu, "\wAktiftir.Sadece Nick Giriniz.", "1", 0);

   menu_setprop(menu, MPROP_EXITNAME, "Cikis")
   menu_display(id, menu, 0)
}
public KullanimKlavuzu2(id, menu, item)
{
   if(item == MENU_EXIT)
   {
      menu_destroy(menu);
      return PLUGIN_HANDLED;
   }
   new Data[6], Name[32], Access, Callback
   menu_item_getinfo(menu, item, Access, Data, sizeof(Data) - 1, Name, sizeof(Name) - 1, Callback)
   new Key = str_to_num(Data)
   switch(Key)
   {
      case 1: {
          KullanimKlavuzu(id)
      }
   }
   menu_destroy(menu);
   return PLUGIN_HANDLED;
}
public mSlot4_Nick(id) {
if(!Slot4_Nick_Giris[id]) {
   RenkliYazi(id,"!t[!g%s!t] !tGecersiz Istek!n.",Reklam)
   return PLUGIN_HANDLED
}
new text[64];
read_args(text,63)
remove_quotes(text)
if(!text[0]) {
   RenkliYazi(id,"!t[!g%s!t]!n: !tErisim Engellendi!n.!tNick Kismi Bos Birakilamaz!n.",Reklam)
   client_cmd(id,"messagemode Slot4_Nick")
   return PLUGIN_HANDLED
}
if(admin_exists(text)) {
   RenkliYazi(id,"!t[!g%s!t]!n: !tErisim Engellendi!n.!tBu Nickte Zaten Bir Slot Var!n.",Reklam)
   client_cmd(id,"messagemode Slot4_Nick")
   return PLUGIN_HANDLED
}
copy(g_szName[id],31,text)
Slot4_Nick_Giris[id] = false;
Slot4_sfre_Giris[id] = true;
client_cmd(id,"messagemode Slot4_Sifre")
RenkliYazi(id,"!t[!g%s!t]!n: !tSlot-4 Sifresini Giriniz!n.",Reklam)
return PLUGIN_HANDLED
}
public mSlot4_Sifre(id) {
if(!Slot4_sfre_Giris[id]) {
   RenkliYazi(id,"!t[!g%s!t]!n: !tGecersiz Istek!n.",Reklam)
   return PLUGIN_HANDLED
}
new text[64];
read_args(text,63)
remove_quotes(text)

add_Slot4(id,g_szName[id],text)

Slot4_sfre_Giris[id] = false;
RenkliYazi(id,"!t[!g%s!t]!n: !tSlotluk Basariyla Aktiflestirildi!n.",Reklam)
RenkliYazi(id,"!t[!g%s!t]!n: !gNick!n: !t%s%s%s  !gSifre!n: !t%s",Reklam,SlotTag,g_szName[id],Slot4Ver,text)

return PLUGIN_HANDLED
}
public mKomutcu1_Nick(id) {
if(!Komutcu1_Nick_Giris[id]) {
   RenkliYazi(id,"!t[!g%s!t] !tGecersiz Istek!n.",Reklam)
   return PLUGIN_HANDLED
}
new text[64];
read_args(text,63)
remove_quotes(text)
if(!text[0]) {
   RenkliYazi(id,"!t[!g%s!t]!n: !tErisim Engellendi!n.!tNick Kismi Bos Birakilamaz!n.",Reklam)
   client_cmd(id,"messagemode Komutcu1_Nick")
   return PLUGIN_HANDLED
}
if(admin_exists(text)) {
   RenkliYazi(id,"!t[!g%s!t]!n: !tErisim Engellendi!n.!tBu Nickte Zaten Bir Komutcu Var!n.",Reklam)
   client_cmd(id,"messagemode Komutcu1_Nick")
   return PLUGIN_HANDLED
}
copy(g_szName[id],31,text)
Komutcu1_Nick_Giris[id] = false;
Komutcu1_sfre_Giris[id] = true;
client_cmd(id,"messagemode Komutcu1_Sifre")
RenkliYazi(id,"!t[!g%s!t]!n: !tKomutcu-1 Sifresini Giriniz!n.",Reklam)
return PLUGIN_HANDLED
}
public mKomutcu1_Sifre(id) {
if(!Komutcu1_sfre_Giris[id]) {
   RenkliYazi(id,"!t[!g%s!t]!n: !tGecersiz Istek!n.",Reklam)
   return PLUGIN_HANDLED
}
new text[64];
read_args(text,63)
remove_quotes(text)

add_Komutcu1(id,g_szName[id],text)

Komutcu1_sfre_Giris[id] = false;
RenkliYazi(id,"!t[!g%s!t]!n: !tKomutculuk Basariyla Aktiflestirildi!n.",Reklam)
RenkliYazi(id,"!t[!g%s!t]!n: !gNick!n: !t%s%s%s  !gSifre!n: !t%s",Reklam,KomutcuTag,g_szName[id],Komutcu1Ver,text)

return PLUGIN_HANDLED
}
public YetkiliSil(id) {
new menu = menu_create("\yYetkili Sil","YetkiliSil2")

new szLine[248];
new LineName[32],LinePW[32],LineAccess[32],LineFlag[32];
new maxlines,txtlen,linee[6];
maxlines = file_size(file,1);
for(new line;line<maxlines;line++) {
   szLine[0] = 0;
   LineName[0] = 0;
   LinePW[0] = 0;
   LineAccess[0] = 0;
   LineFlag[0] = 0;
   read_file(file,line,szLine,247,txtlen)
   
   if(szLine[0]) {
      parse(szLine,LineName,31,LinePW,31,LineAccess,31,LineFlag,31)
      if(equali(LineFlag,"a") && !equali(LineName,";") ) {
         num_to_str(line,linee,5)
         menu_additem(menu,LineName,linee,ADMIN_LEVEL_C)
      }
   }
}
menu_setprop(menu,MPROP_EXIT,MEXIT_ALL)
menu_display(id,menu,0)
return PLUGIN_HANDLED
}
public YetkiliSil2(id,menu,item) {
if(item == MENU_EXIT) {
   menu_destroy(menu)
   return PLUGIN_HANDLED
}
new data[6],name[64];
new access,callback;
menu_item_getinfo(menu,item,access,data,5,name,63,callback)
write_file(file,"",str_to_num(data))
RenkliYazi(id,"!t[!g%s!t]!n: !tYetkili Basariyla Silindi!n.!gNick!n:!t%s",Reklam,name)
server_cmd("amx_reloadadmins")
return PLUGIN_HANDLED
}

public add_Slot4(id,const Name[],const Pw[]) {
new szLine[248],yonetici[32],yetkiler[32];
get_pcvar_string(pFlags4,yetkiler,31)
get_user_name(id,yonetici,31)
formatex(szLine,247,"^"%s%s%s^" ^"%s^" ^"%s^" ^"a^" // Yazan: %s",SlotTag,Name,Slot4Ver,Pw,yetkiler,yonetici)
write_file(file,szLine)
server_cmd("amx_reloadadmins")
return PLUGIN_HANDLED
}

public add_Komutcu1(id,const Name[],const Pw[]) {
new szLine[248],yonetici[32],yetkiler[32];
get_pcvar_string(pFlags10,yetkiler,31)
get_user_name(id,yonetici,31)
formatex(szLine,247,"^"%s%s%s^" ^"%s^" ^"%s^" ^"a^" // Yazan: %s",KomutcuTag,Name,Komutcu1Ver,Pw,yetkiler,yonetici)
write_file(file,szLine)
server_cmd("amx_reloadadmins")
return PLUGIN_HANDLED
}

stock admin_exists(const Name[]) {
new szLine[248];
new LineName[32],blabla[32];
new maxlines,txtlen;
maxlines = file_size(file,1);
for(new line;line<maxlines;line++) {
   read_file(file,line,szLine,247,txtlen)
   parse(szLine,LineName,31,blabla,31)
   if(equali(LineName,Name)) {
      return 1;
   }
}
return 0;
}
stock RenkliYazi(const id, const input[], any:...)
{
   new count = 1, players[32];
   static msg[191];
   vformat(msg, sizeof(msg) - 1, input, 3);

   replace_all(msg, sizeof(msg) - 1, "!n", "^x01"); 
   replace_all(msg, sizeof(msg) - 1, "!g", "^x04"); 
   replace_all(msg, sizeof(msg) - 1, "!t", "^x03"); 
   
   if(id) players[0] = id; else get_players(players, count, "ch"); {
      for(new i = 0; i < count; i++)
      {
         if(is_user_connected(players[i]))
         {
            message_begin(MSG_ONE_UNRELIABLE, get_user_msgid("SayText"), _, players[i]);
            write_byte(players[i]);
            write_string(msg);
            message_end();
         }
      }
   }
}

Yetkiver [istek]

Gönderilme zamanı: Cum Ağu 11, 2017 2:43 pm
gönderen By-Muhammed
bide plugins iniye adminsql yerine bişi yazıoduk o neydi ?

Yetkiver [istek]

Gönderilme zamanı: Cum Ağu 11, 2017 2:49 pm
gönderen legolalp
admin_usersini.amxx sanırım.

Yetkiver [istek]

Gönderilme zamanı: Cum Ağu 11, 2017 2:50 pm
gönderen By-Muhammed
işte onu nası yapcaz reis anlatsana

Yetkiver [istek]

Gönderilme zamanı: Cum Ağu 11, 2017 2:52 pm
gönderen legolalp
redarmygaming yazdı:3.] Eklentinin Tamamen doğru çalışması için plugins.ini konumunu aşağıdaki gibi yapın ;
Resim
Tüm zamanlar UTC+03:00
1. sayfa (Toplam 1 sayfa)

Powered by phpBB® Forum Software © phpBB Limited


Türkçe çeviri: phpBB Türkiye & Türkiye Forum