CSDuragi.COM Forum

Kod: Tümünü seç

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "Vox Round Say"
#define VERSION "1.2"
#define AUTHOR "csduragı"

new rounds_elapsed;
new chat_message;
new play_sound;
new say_text;

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR)
	register_event("HLTV", "new_round", "a", "1=0", "2=0");
	register_event("TextMsg", "restart_round", "a", "2=#Game_will_restart_in");
	play_sound = register_cvar("amx_playsound","1");
	chat_message = register_cvar("mesaj_turu","1");
	say_text = get_user_msgid("SayText");
}
public new_round()
{
	rounds_elapsed += 1;
	
	new map[32]
	get_mapname(map, 31)
	new p_players;
	new p_playernum;
	p_players = get_maxplayers();
	p_playernum = get_playersnum(1);
	
	if(get_pcvar_num(chat_message) == 1)
	{	
		client_printc(0,"!t[Zombie WarS] !yRound: !g%d !yHarita: !g%s !yOyuncular: !t%d!y/!t%d", rounds_elapsed, map, p_playernum, p_players); 
	}
	if(get_pcvar_num(chat_message) == 2)
	{	
		client_print(0,print_center,"[ Round: %d ] - [ Harita: %s ] - [ Oyuncular: %d/%d ]", rounds_elapsed, map, p_playernum, p_players); 
	}
	if(get_pcvar_num(chat_message) == 3)
	{	
		set_dhudmessage(255, 0, 0, -1.0, 0.35, 2, 6.0, 3.0, 0.1, 3.0, false)
		show_dhudmessage(0, "[ Round: %d ] - [ Harita: %s ] - [ Oyuncular: %d/%d ]", rounds_elapsed, map, p_playernum, p_players); 
	}
	if(get_pcvar_num(chat_message) == 4)
	{	
		set_dhudmessage(0, 255, 0, -1.0, 0.35, 2, 2.0, 2.0, 0.1, 3.0, false)
		show_dhudmessage(0, "Round: [ %d ]", rounds_elapsed); 

		set_dhudmessage(255, 0, 0, -1.0, 0.35, 2, 2.0, 2.0, 0.1, 3.0, false)
		show_dhudmessage(0, "^nHarita: [ %s ]", map); 

		set_dhudmessage(150, 150, 150, -1.0, 0.35, 2, 2.0, 2.0, 0.1, 3.0, false)
		show_dhudmessage(0, "^n^nOyuncular: [ %d/%d ]", p_playernum, p_players); 
	}
	if(get_pcvar_num(play_sound) == 1)
	{
		new rndctstr[21]
		num_to_word(rounds_elapsed, rndctstr, 20);
		client_cmd(0, "spk ^"vox/round %s^"",rndctstr)
	}	
	return PLUGIN_CONTINUE;
}
public restart_round()
{
	rounds_elapsed = 0;	
}
stock client_printc(const id, const string[], {Float, Sql, Resul,_}:...) {
	
	new msg[191], players[32], count = 1;
	vformat(msg, sizeof msg - 1, string, 3);
	
	replace_all(msg,190,"!g","^4");
	replace_all(msg,190,"!y","^1");
	replace_all(msg,190,"!t","^3");
	
	if(id)
		players[0] = id;
	else
		get_players(players,count,"ch");
	
	for (new i = 0 ; i < count ; i++)
	{
		if (is_user_connected(players[i]))
		{
			message_begin(MSG_ONE_UNRELIABLE, say_text,_, players[i]);
			write_byte(players[i]);
			write_string(msg);
			message_end();
		}		
	}
}

#if defined _dhudmessage_included
    #endinput
#endif

#define _dhudmessage_included

#include <amxmodx>

stock __dhud_color;
stock __dhud_x;
stock __dhud_y;
stock __dhud_effect;
stock __dhud_fxtime;
stock __dhud_holdtime;
stock __dhud_fadeintime;
stock __dhud_fadeouttime;
stock __dhud_reliable;

stock set_dhudmessage( red = 0, green = 160, blue = 0, Float:x = -1.0, Float:y = 0.65, effects = 2, Float:fxtime = 6.0, Float:holdtime = 3.0, Float:fadeintime = 0.1, Float:fadeouttime = 1.5, bool:reliable = false )
{
    #define clamp_byte(%1)       ( clamp( %1, 0, 255 ) )
    #define pack_color(%1,%2,%3) ( %3 + ( %2 << 8 ) + ( %1 << 16 ) )

    __dhud_color       = pack_color( clamp_byte( red ), clamp_byte( green ), clamp_byte( blue ) );
    __dhud_x           = _:x;
    __dhud_y           = _:y;
    __dhud_effect      = effects;
    __dhud_fxtime      = _:fxtime;
    __dhud_holdtime    = _:holdtime;
    __dhud_fadeintime  = _:fadeintime;
    __dhud_fadeouttime = _:fadeouttime;
    __dhud_reliable    = _:reliable;

    return 1;
}

stock show_dhudmessage( index, const message[], any:... )
{
    new buffer[ 128 ];
    new numArguments = numargs();

    if( numArguments == 2 )
    {
        send_dhudMessage( index, message );
    }
    else if( index || numArguments == 3 )
    {
        vformat( buffer, charsmax( buffer ), message, 3 );
        send_dhudMessage( index, buffer );
    }
    else
    {
        new playersList[ 32 ], numPlayers;
        get_players( playersList, numPlayers, "ch" );

        if( !numPlayers )
        {
            return 0;
        }

        new Array:handleArrayML = ArrayCreate();

        for( new i = 2, j; i < numArguments; i++ )
        {
            if( getarg( i ) == LANG_PLAYER )
            {
                while( ( buffer[ j ] = getarg( i + 1, j++ ) ) ) {}
                j = 0;

                if( GetLangTransKey( buffer ) != TransKey_Bad )
                {
                    ArrayPushCell( handleArrayML, i++ );
                }
            }
        }

        new size = ArraySize( handleArrayML );

        if( !size )
        {
            vformat( buffer, charsmax( buffer ), message, 3 );
            send_dhudMessage( index, buffer );
        }
        else
        {
            for( new i = 0, j; i < numPlayers; i++ )
            {
                index = playersList[ i ];

                for( j = 0; j < size; j++ )
                {
                    setarg( ArrayGetCell( handleArrayML, j ), 0, index );
                }

                vformat( buffer, charsmax( buffer ), message, 3 );
                send_dhudMessage( index, buffer );
            }
        }

        ArrayDestroy( handleArrayML );
    }

    return 1;
}

stock send_dhudMessage( const index, const message[] )
{
    message_begin( __dhud_reliable ? ( index ? MSG_ONE : MSG_ALL ) : ( index ? MSG_ONE_UNRELIABLE : MSG_BROADCAST ), SVC_DIRECTOR, _, index );
    {
        write_byte( strlen( message ) + 31 );
        write_byte( DRC_CMD_MESSAGE );
        write_byte( __dhud_effect );
        write_long( __dhud_color );
        write_long( __dhud_x );
        write_long( __dhud_y );
        write_long( __dhud_fadeintime );
        write_long( __dhud_fadeouttime );
        write_long( __dhud_holdtime );
        write_long( __dhud_fxtime );
        write_string( message );
    }
    message_end();
}