CSDuragi.COM Forum

Kod: Tümünü seç

#include <amxmodx>
#include <amxmisc>
#include <fakemeta>
#include <hamsandwich>
#include <engine>
#include <xs>

#define PLUGIN "Killed by (CS:S / CS:GO) effect"
#define VERSION "1.1"
#define AUTHOR "Xalus"

#define Camera_Distance_Min 60.0
#define Camera_Distance_Max 160.0

#define m_flNextSpecButtonTime 100
#define m_fDeadTime            354

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)

    // Ham
    RegisterHam(Ham_Spawn, "player", "Ham_PlayerSpawn_Post", 1)
    RegisterHam(Ham_Killed, "player", "Ham_PlayerKilled_Post", 1)
}
// Client
public client_connect(id)
{
    set_pev(id, pev_groupinfo, 1<<0)
}

// Ham
public Ham_PlayerSpawn_Post(id)
{
    if(is_user_alive(id))
    {
        set_pev(id, pev_groupinfo, 1<<0)

        if(task_exists(id + 556165))
        {
            remove_task(id + 556165)

            client_unfreeze(id)
        }
    }
}

public Ham_PlayerKilled_Post(id, killer)
{
    if(is_user_connected(id) && is_user_connected(killer)
    && id != killer)
    {
            // Credits to ConnorMcLeod
        set_pev(id, pev_deadflag, DEAD_DEAD)
        new Float:flTime = get_gametime()
        set_pdata_float(id, m_fDeadTime, flTime - 3.1)

        set_pdata_float(id, m_flNextSpecButtonTime, get_gametime() + 3.0)

        engclient_cmd(id, "specmode", "4")

        // Freeze player
        client_freeze(id, killer)
    }
}

public client_freeze(id, killer)
{
    if(is_user_connected(id)
    && pev(id, pev_groupinfo) == 1<<0)
    {
        new Float:floatOrigin[3][3]
        pev(killer, pev_origin, floatOrigin[0])

        new intTrace = create_tr2()

        new arrayPlayers[32], intPlayers
        get_players(arrayPlayers, intPlayers, "a")

        for(new i = 0; i < intPlayers; i++)
        {
            pev(arrayPlayers[i], pev_origin, floatOrigin[2])

            engfunc(EngFunc_TraceLine, floatOrigin[0], floatOrigin[2], IGNORE_MONSTERS, 0, intTrace)
            get_tr2(intTrace, TR_vecEndPos, floatOrigin[1])

            if(xs_vec_equal(Float:floatOrigin[2], Float:floatOrigin[1])
            || arrayPlayers[i] == id)
            {
                client_fakeplayer(id, arrayPlayers[i], floatOrigin[1])
            }
        }
        free_tr2(intTrace)

        set_pev(id, pev_groupinfo, 1<<id)

        set_pev(id, pev_deadflag, DEAD_DYING)

        // Hudmessage
        new strName[32]
        get_user_name(killer, strName, charsmax(strName))

        set_dhudmessage(250, 250, 250, 0.10, 0.50, 0, 3.0, 2.4, 0.1, 0.5)
        show_dhudmessage(id, "%s", strName)

        set_dhudmessage(250, 0, 0, 0.10, 0.54, 0, 3.0, 2.4, 0.1, 0.5)
        show_dhudmessage(id, "Killed you")

        // Unfreeze screen
        set_task(3.0, "Task_ScreenUnfreeze", id + 556165)
    }
}

// Task
public Task_ScreenUnfreeze(id)
{
    id -= 556165

    client_unfreeze(id)
}


// Stock
stock client_unfreeze(id)
{
        // Remove all fake players of the player
    new strClassname[32]
    formatex(strClassname, charsmax(strClassname), "Fakeplayer_%i", id)
    remove_entity_name(strClassname)

    if(is_user_connected(id))
    {
        set_pev(id, pev_groupinfo, 1<<0)
    }
}
stock client_fakeplayer(id, target, Float:flOrigin[3])
{
        // Create
    new entity = engfunc(EngFunc_CreateNamedEntity, engfunc(EngFunc_AllocString, "info_target"))

    if(!entity)
        return 0;

    //give_weapon(id, entity)

    new strTemp[50], Float:floatTemp[3]

    // Bugfix ?
    set_pev(entity, pev_aiment, 0)

    // "Worls"
    set_pev(entity, pev_groupinfo, 1<<id) // id + 1

    // Origin
    set_pev(entity, pev_origin, flOrigin)

    // Angle
    pev(target, pev_angles, floatTemp)
    floatTemp[0] = 0.0
    floatTemp[2] = 0.0
    set_pev(entity, pev_angles, floatTemp)
    set_pev(entity, pev_v_angle, floatTemp)

    // Model
    new strModel[32]
    get_user_info(target, "model", strModel, charsmax(strModel))
    formatex(strTemp, charsmax(strTemp), "models/player/%s/%s.mdl", strModel, strModel)
    engfunc(EngFunc_SetModel, entity, strTemp)

    // Classname
    formatex(strTemp, charsmax(strTemp), "Fakeplayer_%i", id)
    set_pev(entity, pev_classname, strTemp)

    // Movement
    set_pev(entity, pev_movetype, MOVETYPE_NOCLIP)
    set_pev(entity, pev_solid, SOLID_NOT)

    // Realistic shizzle
    entity_set_float(entity, EV_FL_animtime, get_gametime())
    entity_set_float(entity, EV_FL_framerate,  0.0)

    pev(target, pev_frame, floatTemp[0])
    entity_set_float(entity, EV_FL_frame, floatTemp[0])

    new intSequence = pev(target, pev_gaitsequence)

    // Walking is not an option!
    if(intSequence == 3)
        intSequence = 1

    if(id == target)
        intSequence = random_num(103,110)

    entity_set_int(entity, EV_INT_sequence, intSequence);

    client_fakeweapon(id, target, entity, strTemp)

    return entity;
}
stock client_fakeweapon(id, target, ent, classname[])
{
    new entity = engfunc(EngFunc_CreateNamedEntity, engfunc(EngFunc_AllocString, "info_target"))

    if(!entity)
        return 0

    set_pev(entity, pev_groupinfo, 1<<id)//  id + 1

    set_pev(entity, pev_classname, classname)

    set_pev(entity, pev_movetype, MOVETYPE_FOLLOW)
    set_pev(entity, pev_solid, SOLID_NOT)

    set_pev(entity, pev_aiment, ent)

    new strTemp[50], intWeaponid
    if(is_user_connected(target))
    {
        intWeaponid = get_user_weapon(target)
    }
    if(!intWeaponid)
        intWeaponid = random(2) ? CSW_AK47 : CSW_M4A1

    get_weaponname(intWeaponid, strTemp, charsmax(strTemp))
    replace(strTemp, charsmax(strTemp), "weapon_", "models/p_")
    add(strTemp, charsmax(strTemp), ".mdl")

    // Crash fix
    replace(strTemp, charsmax(strTemp), "navy", "")

    engfunc(EngFunc_SetModel, entity, strTemp)

    return entity
}

// Idea by Xalus, code by Exolent
stock origin_behind( Float:vecAngles[3], Float:vecOrigin[ 3 ], Float:flDistance, Float:vecOutput[ 3 ] )
{
    engfunc(EngFunc_MakeVectors, vecAngles)
    global_get(glb_v_forward, vecAngles)

    xs_vec_mul_scalar(vecAngles, -flDistance, vecAngles)

    xs_vec_add(vecOrigin, vecAngles, vecOutput)
}