Rütbeye Göre Model Değişimi

[msbeden]

Merhabalar. Kullandığım bir rütbe sistemim var. Rütbe sistemimde vs. herhangi bir sorun yok. Güzelce alıyorum değerleri. Ancak model değişimini kalıcı yapamıyorum. Doğduğunda 1 2 saniye değişiyor. Sonra eski haline geliyor. Bunu nasıl değiştirebilirim. Herkesin modeli değişmeyecek rütbeye göre değişecek.

Kod: Tümünü seç

#include <amxmodx>
//crxranks Hakkında -> Rütbe tespiti için gerekli.
#include <crxranks>
//hamsandwich Hakkında -> Rütbe skin değişimi için oyuncu doğmasını algılar.
#include <cstrike>
#include <hamsandwich>

public plugin_init() 
{
    register_plugin("Rutbeye Odul Sistemi", "1.0", "msbeden");
    RegisterHam(Ham_Spawn, "player", "FwdHamSpawn", 1);

    return PLUGIN_CONTINUE
}

public plugin_precache() 
{
    precache_model("models/player/subayct/subayct.mdl");
    precache_model("models/player/subayte/subayte.mdl");

    return PLUGIN_CONTINUE
}

public FwdHamSpawn(oyuncu_id)
{
    new oyuncu_name[32];
    get_user_name(oyuncu_id,oyuncu_name,31);

    new rutbe = crxranks_get_user_level(oyuncu_id);

    if (rutbe >= 8) {
        new CsTeams:userTeam = cs_get_user_team(oyuncu_id)
        if (userTeam == CS_TEAM_T) {
            cs_reset_user_model(oyuncu_id);
            cs_set_user_model(oyuncu_id, "subayte");
        } else if(userTeam == CS_TEAM_CT) {
            cs_reset_user_model(oyuncu_id);
            cs_set_user_model(oyuncu_id, "subayct");
        } else {
            cs_reset_user_model(oyuncu_id)
        }
    } else {
        
    }
}

[msbeden]

Cevap bekliyorum

[Colditz]

Eklenti CSDurağı'nda mı kullanılacak yoksa başka sunucuda mı?

[msbeden]

Csduraginda kullanıyorum. Ama 1 2 saniye sonra geçiyor.

[Colditz]

Denemedim, bir dener misin?

Kod: Tümünü seç

#include <amxmodx>
#include <reapi>
#include <crxranks>

new const model_t[] = "subayte";
new const model_ct[] = "subayct";

public plugin_init() {
       register_plugin("Rutbe Model", "1.0", "PurposeLess");

       RegisterHookChain(RG_CBasePlayer_Spawn, "@CBasePlayer_Spawn", .post=true);
}

@CBasePlayer_Spawn(const id)
{
       new name[32];
       get_user_name(id, name, charsmax(name));

       new rutbe = crxranks_get_user_level(id);

       if(rutbe >= 8)
       {
              new TeamName:team = get_member(id, m_iTeam);

              switch(team)
              {
                       case TEAM_TERRORIST: {
                            rg_set_user_model(id, model_t);
                       }
                       case TEAM_CT: {
                            rg_set_user_model(id, model_ct);
                       }
              }
       }
}

public plugin_precache() 
{
       precache_player_model(model_t);
       precache_player_model(model_ct);
}

precache_player_model(const modelname[])
{
       new modelspath[32];
       formatex(modelspath, charsmax(modelspath), "models/player/%s/%s.mdl", modelname, modelname);

       precache_model(modelspath);
}

[msbeden]

Teşekkür ederim. Sadece precache_player_model() fonksiyonunda bir hata oluştu, onu halledince çalıştı. İyi çalışmalar dilerim.

[Colditz]

Teşekkür ederim. Sadece precache_player_model() fonksiyonunda bir hata oluştu, onu halledince çalıştı. İyi çalışmalar dilerim.

Program vs. olmadığı için hastebin sitesinden yazmak zorunda kalıyorum bu yüzden compile etme şansım olmuyor.
Düzelttiyseniz sıkıntı yok. İyi kullanmalar.